Internet Explorer'ı komut satırından başlatılacak varsayılan tarayıcı olarak ayarlamak mümkün müdür?

Yalnızca Internet Explorer altında çalışan bir web uygulamam var, ancak Firefox varsayılan tarayıcıysa, çalışmaz. Kullanıcılar bir etki alanı ortamında ve uygulamamızı bir toplu işlemden bu şekilde başlatmaya çalışsam da:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

tarayıcıyı manuel olarak değiştirmediğim sürece uygulama başlamıyor.

Bu komut IE'yi varsayılan tarayıcı olarak ayarlar:

shmgrate.exe OcinstallreinstallIE

Bu politika , insanların varsayılan tarayıcıyı belirlemesini durdurmalıdır.

bunu deneyebilirsin, işe yarayacak

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

komutunuzdaki hata, startilk alıntılanan dizenin uygulamanın başlığı olmasını beklemekti, bu durumda boş bırakabilirsiniz.

iexplorer.exesistemin varsayılan web tarayıcısı olarak ayarlamak için , uzantıları dosya türleriyle ve dosya türlerini aşağıdaki gibi yürütülebilir dosyalarla ilişkilendiren assocve ftypekomutları kullanabilirsiniz :

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 buradaki argüman - bu, programa girdi olarak gönderebileceğiniz URL veya dosya

Windows Vista ve üzeri, IE 7+

Aşağıdaki toplu komut dosyası , Varsayılan Programlar denetim masası uygulamasından Bu programları varsayılan olarak ayarla'yı tıklatarak taklit eder . Vista / 7 ve IE 7 / IE 11 ile test edilmiştir.

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

Uyarılar

Herhangi bir web tarayıcı uygulaması, Başlat menüsünde Internet istemcisi olarak görünmek üzere kaydolabilir. Bu görünürlük, bir uygulamanın dosya ve protokol türleri için uygun kayıt ile birleştiğinde , uygulamaya varsayılan tarayıcı durumu verir. Varsayılan web tarayıcısı, sistemin herhangi bir yerinden rastgele URL'ler başlatmak için kullanılır.

Not Windows 7 ve sonraki sürümlerde mevcut [başlat menüsü bağlantısı] kayıtları yoksayılır. Bu kayıt Windows 7'den itibaren kullanımdan kaldırılmıştır.

_{Kaynak: Windows Başlat Menüsü ile Internet Tarayıcı veya E-posta İstemcisi Nasıl Kaydedilir}

­­

Dosya ve protokol ilişkilendirmeleri için hiyerarşik kayıt defteri yapısı, makine düzeyi varsayılanlara göre kullanıcı başına varsayılanlara öncelik verir.

_{Kaynak: Varsayılan Programlar}

Bir bat dosyasına iki satırın altına ekleyebilirsiniz

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

Yarasa çalıştırıldıktan sonra, yukarıdaki iki komut satırı kayıt defteri değerlerini değiştirme amaçlı olduğundan yeniden başlatın / oturumu kapatın ve yeniden oturum açın.

Aditinal ayrıntıları burada bulabilirsiniz

(Sabit) - Internet Explorer'ı Varsayılan Tarayıcı olarak ayarlayabilir! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

Varsayılan tarayıcıyı komut satırından ayarlama hakkında bilmiyorum, ancak grup ilkesi aracılığıyla etki alanını ayarlayabilir ve uygulayabilirsiniz.

İşte başlamanız için bir şey:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

Sadece startkomut veya toplu iş dosyasını almak için bırakın .

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Windows 8 (IE 10+) için kolay VBS betiği:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

IE'yi varsayılan olarak değiştirmek için IE sayfasını başlatır ve kabul etmek için düğmesine tıklayın.