kaydırma tekerleği topunu yok için çare?

İztopu almayı düşünüyorum ve seçeneğim Logitech izci mermeri. Ama sonra kaydırma tekerleği olmadığını buldum. Bununla nasıl başa çıkıyorsun? Kesinlikle kaydırma tekerleği ile bir topunu satın almak istiyorum? Facebook kullanarak çok kaydırma yapıyorum.

İşaret parmağımla ve orta parmaklarımla tıklamak istemiyorum, bu nedenle bazı trackball fareleri Trackman Wheel gibi benim için çalışmayacak.

Eğer Windows kullanıyorsanız, AutoHotKey'i denemeyi öneririm, diğer kullanıcılar Marble Mouse ile kaydırma işlemlerini çoktan denediler (betiği en altta kullandım):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

Logitech'in sürücüleri ile gelen çözümü garip: 4 yönlü kaydırmayı etkinleştirmek için bir kez tıklayın ve devre dışı bırakmak için tekrar tıklayın. Neyin peşindeysem onu ​​tutup kaydıramazsın. Yazılımlarını kaldırırken yaralandım.

Aynı iztopuna sahibim ve çözüm çok şık: seçili bir düğmeyi tıkladığınızda topun kendisi kaydırma tekerleği haline geliyor. Küçük parmağınızla bastığım büyük sağ düğmeyi seçtim.

Bu çok kullanışlıdır ve alışması sadece birkaç gün sürer.

Herhangi bir kaydırma tekerleğinin (fare veya hareket topunun) kullanılamaz bir şey olduğunu hızlı bir şekilde düşüneceksiniz. İnan bana, buna değer ;-)

Avantajları:

• 1D yerine 2D kaydırma
• tekerlekten daha hızlı ve daha hassas kaydırma
• Uzun kaydırma için daha rahat (topun ataleti sayesinde). Facebook örneğiniz için mükemmel.

Artık onsuz yaşayamam.

Bunu herhangi bir Linux işletim sistemi altında yapılandırmak zor değildir. Yalnızca bir /etc/X11/xorg.conf dosyası oluşturmanızı gerektirir (burada config'umu görün: Xorg.conf dosyasını düzenlemeden Linux altında bir hareket topunu yapılandırın )

Daha fazla ayrıntı burada bulunabilir: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

Windows'ta deneyimim yok ama bir yapılandırma aracının hareket topuyla birlikte verildiğini düşünüyorum.

Özellikle bu fare için geliştirilen Marble Mouse Scroll Wheel'ı deneyebilirsiniz:

Mermer Fare Kaydırma Tekerleği veya sadece Mermer Kaydırma, herhangi bir iztopunda veya farede bir kaydırma tekerleğini simüle etmek için tasarlanmış küçük bir programdır. Logitech Marble Mouse için özel olarak tasarlanmıştır, ancak herhangi bir standart fare veya iz topuyla çalışabilir. Windows 2000 ve üstü için tasarlanmıştır.

Marble Scroll, Logitech'in Autoscroll ve Universal Scroll işlevlerinin yerine geçer; ne gerçek bir kaydırma tekerleğini uygun şekilde taklit etmeyin ve her ikisi de sınırlama ve kusurlara sahiptir.

Marble Scroll, herhangi bir fare veya izleme topu ile çalışır ve Logitech'in SetPoint veya MouseWare sürücülerinin kurulmasını gerektirmez.

Özellikler

• İkiden fazla düğmeli farelere kaydırma tekerleği ekleyin
• Kaydırma tekerleğini destekleyen çoğu uygulamayla uyumluluk (herhangi bir giriş türü için)
• Ayarlanabilir hızlanma
• Ayarlanabilir kaydırma mesafesi ("adım" başına - aşağıya bakınız)
• Gerçek bir fare tekerleğini simüle etmek için kademeli kaydırma
• Hızlı sol / sağ elle mod değiştirici
• Tepsi simgesine tıklayarak hızlı etkinleştirme / devre dışı bırakma
• Sistem kaynakları üzerinde küçük ve hafif

Ürünün web sitesi şu anda kapalı görünüyor, ancak burada sitenin Archive.org'daki metninin bir kopyası .

Bir indirme bağlantısı burada .

AutoHotKey çözümlerine çok benzeyen basit bir 100 satır C ++ alternatifi var.

• X Düğmelerinden birini basılı tutarken hareket topunu hareket ettirerek dikey / yatay kaydırma tekerleği olayları gönderme ve
• topunu hareket ettirmeden bir X-Düğmesine basıp bırakırken orta klik.

https://github.com/Seelge/TrackballScroll

Düzenleme: Yeni sürümler bir systray simgesi sağlar, Windows 10'da çalışır ve C # temellidir.

İşte kullandığım AutoHotKey betiği. Sol küçük düğmeyi basılı tutarak ve topu yukarı / aşağı yuvarlayarak kaydırın. Ancak soldaki küçük butona tıklamak, BACK yapar. Ayrıca sola / sağa kayabilir ancak bu benim için çok hassastır, bu yüzden burada yorumlanır (ile başlayan blok ;timesX := Abs(movedx) / 4).

Orijinal sürümü http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-using-right-mouse-button/ adresinde buldum . Versiyonumu orada başka bir kişi8923 olarak yayınladım.

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

Logitech'in kaydırma tekerleği simülasyonu uygulaması çok yazık oldu. Sürücüleri bunu yapacak bir özellik vaat ediyor, ancak tüm uygulamalar için işe yaramadı ve işe yaramaz hale geldi. Mükemmel fareyi yaratmaya çok yakındılar! : s

Bulduğum tek geçici çözüm, bunun için bir AutoHotkey komut dosyası kullanmak . Bununla beraber küçük sol / sağ düğmelerinin yukarı ve aşağı kaydırılmasını sağlayabilirsiniz. Mükemmel çalışıyor, ancak yapılandırılmasını sağlamak için gerçek bir güçlük: önce AutoHotkey temellerini öğrenmeniz gerekir. Bunu yapmaya karar verirseniz, işte AutoHotkey betiğim. Jerbo'nun orijinal senaryosunun bir uyarlamasıdır . Tek bir tıklama normal hızda kaydırmaya başlayacaktır, ancak çift veya üç tıklama daha hızlı kaydırmaya başlayacaktır.

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

Logitech Marble fareyi yeni aldım ve ayrıca kaydırma sorunu yaşadım. Bu yüzden AutoHotKey'de bu senaryoyu hazırladım. Soldaki Xbutton kaydırma sağlar; aşağıdayken topla dikey ve yatay olarak kaydırma yapabilir ve tarayıcıda sol ve sağ düğmelerle ileri ve geri gidebilirsiniz. Sağ Xdüğmesi orta düğmeyle aynı etkiye sahiptir.

Windows 7’deyim.

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

İşletim sisteminize bağlı olarak, tutulduğunda işaretçiyi hareket ettirerek kaydırmayı etkinleştirmek için düğmelerden birini yapılandırabilirsiniz. Örneğin, aşağıdaki script bunu faremin butonu 10'da (Logitech MX310'un "üst ortası" butonu) etkinleştirir:

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

Kaydırma tekerleğine sahip mermer faresi (fareler) vardır. Aksi takdirde, bir kaydırma fonksiyonunu devreye sokmak için düğmelerden birinin kullanımı ile birlikte tekerlekli olmayan bir fare için bir uygulama veya bir komut dosyası gerekebilir (kabul edilebilir bir çözüm olarak başka bir cevaba yapılan bir yorumda not ettiğiniz).

Öyleyse "Neden tekerleği yeniden icat ettin?" bu durumda iyi bir atasözü.

Bu örneklerde, eleman fiziksel olarak monte edilmiştir ve aralarından seçim yapabileceğiniz birçok tip vardır. Aşağıda iki örnek ve stil bulunmaktadır.

Veya böyle bir şey: Adesso

İki geleneksel olmayan seçenek

• Hareket topuna ek olarak bir Apple Magic İzleme Paneli kullanın. (Bu benim şu andaki çözümüm) http://www.apple.com/magictrackpad/

• Bir leapmotion kontrol cihazı satın alın ve hareket topuna ek olarak kullanın. Yukarı ve aşağı kaydırmak için elinizi cihazın önünde sallayın. https://www.leapmotion.com/product

Resim kredisi http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

Basit (ve ergonomik bir cesaret) diyorum ki kaydırma fonksiyonunu sol elinize almanız gerekiyor.

Bu, sol elinizle bir fare kullanarak / sol kenarında yerleşik bir kaydırma tekerleği bulunan bir klavye kullanarak / Mkey ( http: // gibi bir program bulunan programlanabilir bir tuş takımının tuşlarına kaydırma işlevleri atayarak sağlanabilir. www.seriosoft.org/en/index.php ).

Neden bunun daha ergonomik olduğunu düşünüyorum - çünkü bu yaklaşım gerginliği her iki elinize daha eşit olarak dağıtır. (Bu konuda daha fazla bilgi için: http://capsoff.org/checklist ).

Windows7'deyim ve Kensington Orbit Optik Trackball'ını kaydırma yapmadan kullanıyorum - bu, AHK komut dosyalarının ve diğerlerinin işaret ettiği uygulamaların çoğunun gerektirdiği X düğmeleri olmadan, iki düğmeli bir izleme topudur .

Ancak, MouseImp benim için Windows7'de çalışıyor. BT yapılandırılabilir, ancak right-click + rollbana bir kaydırma ekranı gösterecek şekilde ayarlamıştım . Bir sürükle gibi, bu yüzden işaretçi hareket eder ve bir seferde sadece bir ekran var [güncelleme: kaydırma hızı yapılandırılabilir, bu nedenle "bir sayfadan daha fazla olabilir]].

Aynı zamanda, Kensington's TrackballWorks bana bir sayfa aşağı kaydırma sağlayacak şekilde yapılandırıldı left-click + right-click. Maalesef, bir seferde bir sayfa (bir veya diğer) geri kaydırma yapamaz.

Bu bir ürün fişi değil - bu model / trackball tipi ile çalışırken bulduğum şeydi .

Uyarma: sürekli sağa ve sola tıklamaktasınız ve bu karışıklığa yol açabilir ve sadece kaydırma işlemini durdurmak istediğinizde / js-aktifleştirilen bağlantıların izlenmesine neden olabilirsiniz . :::iç çekmek:::

Kensington'dan bir yörünge kablosuz iztopu aldım, bu oldukça şaşırtıcı. Topunuz var, her iki tarafta da iki düğmeniz var ve hareket topunun dışında sayfayı yukarı veya aşağı kaydırmayı mümkün kılan bir daire var. Gerçekten işe yarıyor ve ben Windows ve Mac OSX'te kullanıyorum.

Aslında AutoHotkey'i bir süre önce kullanarak bunun için bir şey yaptım ve burada da paylaşacağımı düşündüm: Mouse Wheel Emulator

Bu, sol ve sağ fare düğmelerini tutarken fareyi hareket ettirerek fare tekerleğinin kaydırılmasını öykünür.

Aynı zamanda, sol ve sağ fare düğmelerini tıklatarak da orta tıklamayı taklit edebilirsiniz.

Windows 7 için, Internet Explorer dahil olmak üzere tüm uygulamalarda kaydırma yapmanıza olanak sağlayan başka bir çözüm:

1. AutoHotKey'i yükleyin .
2. Kaydet bu senaryoyu olarak scroll.ahkMasaüstüne.
3. Sağ tıklayın scroll.ahk.
4. Komut Dosyasını Çalıştır'ı seçin .
5. İstenirse onaylayın.

Bu, hareket topunu hareket ettirirken küçük sağ düğmenin dikey olarak kaydırılmasını sağlar. Küçük sol düğme geri düğmesidir.

Erik Elmore'un koduna olan bağlantının ortadan kalkması durumunda, işte burada:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <erik@ironsavior.net>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

Burada başka bir Trackman Marble kullanıcısı.

Kaydırma öykünmesi için X-Mouse Button Control kullanıyorum . Bu özellik uygulaması orada (henüz?) Mükemmel değil, ancak kendi SetPoint yazılımında Logitech uygulamasından çok daha kullanışlı.

XMBC'yi AutoHotKey ile karıştırmak istemeyen ve sadece işe yarayan bir şey arayan herkese öneririm.