Bir toplu iş dosyasında klasörler arasında nasıl dolaşılır ve uzantıları yeniden adlandırılır?

Çalıştırabileceğim tek bir klasör seçerek

ren *.jpeg *.png

Birden fazla klasörüm var. Tüm klasörler arasında dolaşacak ve içindeki dosyaları yeniden adlandıracak bir toplu iş dosyası oluşturmak istiyorum.

Mesela klasörüm var TEST1 ve TEST2 kök dizini içinde TEST. Tüm adlarını yeniden adlandıracak bir toplu iş oluşturmak istiyorum .jpeg içindeki dosyalar TEST1 ve TEST2 için .png.

FOR /R "E:\TEST\" %%G in (*.jpeg) DO ren *.jpeg *.png

Bir hata alıyorum:

Sistem belirtilen dosyayı bulamıyor

Ben sorunu anlamıyorum.

Uygulamıyorsun for komut ren aksiyon.

for /r "E:\test\" %%G in (*.jpeg) do ren "%%~G" *.png

Değişmen gerek %% için % Bunu etkileşimli olarak yapıyorsanız ve toplu iş dosyasında değilse.

~ boşluk içeren yollarla ilgili olası hataları önlemek için yeniden eklenen tırnakları çıkarır.

Veya, biraz daha kısa bir astar istiyorsanız, işte bunun bir kombinasyonuyla nasıl yapılacağını REN komuta ve GLOBAL komuta içinde JP Yazılımının TCC / LE'si :

GLOBAL REN *.JPEG *.PNG

kullanım GLOBAL 'ler /I Sıfır olmayan çıkış kodlarını yoksaymak istiyorsanız, seçeneği REN elbette.

Tam bir çözüm aşağıdadır.

Değişkenleri "değişkenler" bölümünde ayarlayın:

@echo off

::only to tell user what this bat are doing
echo.1.initializing...

::enable that thing to allow, for example, incremental counter in a for loop :)
echo.- EnableDelayedExpansion
SETLOCAL EnableDelayedExpansion

::variables
echo.- variables
:: - place here the absolute root path of your files
set path2work="C:\Documents and Settings\ubirajara2\Desktop\Nova pasta"
set extension2exclude=jpeg
set extension2put=png

::only an auxiliar variable
set pathbak=%cd%

::go to %path2work% and its drive letter
echo.- entering the path you want
for /f "delims=¯" %%i in ('echo.%path2work%') do %%~di
cd %path2work%

::search all subfolders and save them to a temp file
echo.- searching for subfolders
echo.%path2work%>%temp%\tmpvar.txt
for /f "delims=¯" %%i in ('dir /s /b /on /ad') do echo."%%i">>%temp%\tmpvar.txt

::execute command for root folder and all found subfolders
echo.
echo.2.executing...
for /f "delims=¯" %%i in (%temp%\tmpvar.txt) do (
  cd %%i
  echo.- in folder: %%i
  for /f "delims=¯" %%j in ('dir /b /on /a-d *.%extension2exclude%') do (
    set newname=%%~nj.%extension2put%
    echo.- renaming from "%%j" to "!newname!"...
    ren "%%j" "!newname!"
  )
)

echo.
echo.3.exiting...
::return to %pathbak% and its driveletter
for /f "delims=¯" %%i in ('echo.%pathbak%') do %%~di
cd %pathbak%

@echo on