Gizli dosyaları kaldırmak için bir Mac Terminal komut dosyası var mı?

Araba stereo cihazım USB flash sürücülerden müzik çalabilir, bu yüzden bir iTunes çalma listesinden MP3 kopyalamayı sordum . Bu iyi çalıştı, ancak stereom MP3 dosyalarını çalmayacaktı. Sonunda flash sürücüyü Windows 7 çalıştıran iş bilgisayarıma koydum ve sorunu buldum: formattaki bir dizi gizli dosya ._[filename].mp3da yüklendi.

Windows'da dosyaları özniteliklere göre silebileceğinizi biliyorum ve aynı şeyi Terminal'de yapıp yapamayacağınızı merak ediyordum. Muhtemelen Birim ile parametre olarak çalıştırabileceğim bir komut dosyası ile?

Bu dosyalar OS X'te gizlidir, çünkü bunlar .varsayılan olarak Finder'da başlar ve bu nedenle Finder'da gösterilmez. Bu dosyalarda bunun dışında özel bir özellik ayarlanmamıştır.

Çok basit bir yaklaşım, bir nokta ve alt çizgi ile başlayan tüm dosyaları silmek olacaktır:

find /Volumes/<your-volume-name> -name '._*' -type f -delete

Güvenlik notu:-delete Hangi dosyaların kaldırılacağını görmek için bunu olmadan çalıştırın . Ve bunu hiçbir zaman tüm Mac HD'nizde değil, sadece USB sürücünüzde yapmayın .

Bazı ek bilgiler için: Bu dosyalara "Kaynak Çatalları" denir ve bazen silmek istemediğiniz bilgileri içerir. Kullanım durumunda, bu iyi olmalı. BlueHarvest kullanarak bu dosyaların oluşturulmasını kalıcı olarak devre dışı bırakabilirsiniz . Ayrıca, bunların hacimlerini temizlediğini iddia eden bir uygulama var, ancak denemedim ve beta, bu yüzden dikkatli kullanın: Gizli Temizleyici .

Terminal tipinde benim için çalışan bir çözüm daha (MacOS 10.6.8):

dot_clean "/Volumes/<your-volume-name>"

Benim araba stereo ile aynı sorunu vardı, 1 dosya / 2 oynanamaz, çünkü oyuncu MAC OS tarafından oluşturulan nokta dosyasının bir müzik dosyası olduğunu düşünüyor ... Sonra bu yazı gerçekten yararlı buldum, teşekkürler.

Şimdi Mavericks için geliştirilmiş ve ücretsiz bir çözümle geri dönüyorum:

1. AppleScript komut dosyasını çalıştırmak için bir Automator Uygulaması oluşturma

2. Bu komut dosyasını kullanın:

   on run {input, parameters}
       try
           tell application "Finder" to set allDrives to the name of every disk whose local volume is true and startup is false
           set driveName to {choose from list allDrives with title "DiskCleaner" with prompt "Disk to Clean and Eject:" OK button name "Clean and Eject" cancel button name "Abort"} as text
           set getDriveIdentifier to "diskutil info " & quoted form of driveName & " | grep Ident | awk '{print $3}'"
           set driveIdentifier to do shell script getDriveIdentifier
           try
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete"
               do shell script "rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}"
               display notification "Disk Cleaned"
           on error
               try
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete" with administrator privileges
                   do shell script "sudo rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}" with administrator privileges
                   display notification "Disk Cleaned"
               on error
                   display notification "Can't Clean, Permission Denied"
               end try
           end try
           delay 1
           try
               do shell script "diskutil eject " & driveIdentifier
               display notification "Disk Ejected"
           on error
               display notification "Can't Eject, Disk in Use"
           end try
       on error
           display notification "No Disk to Clean and Eject"
       end try
   end run
   

3. Uygulamayı örneğin DiskCleaner.app kaydedin

Bu komut dosyası sizden temizlemek ve çıkarmak için USB diski seçmenizi ister. Ardından USB diski temizler (geçerli olanlarla başarısız olursa yönetici kimlik bilgileriyle çalışır), ardından mümkünse çıkarın.

Tabii ki hala iyileştirilecek bir yer var, bu senaryoyu kendim için yaptım!

Ayrıca daha fazla dosyayı temizlemek için kod satırları ekleme esnekliğine sahipsiniz.

Zevk almak!

Terminal sizi korkutuyorsa aynı şeyi gerçekleştirmek için Automator'u da kullanabilirsiniz:

Bu komut dosyası, USB sürücülerdeki gizli dosyaları veya dizinleri silmek için kullanılır. https://github.com/ulasyurtsever/delete-hidden-files-or-directories