Windows'u güncelleştirmeleri denetlemeye nasıl zorlarım?

Yeni bir Windows kurulumundan sonra - XP veya 7 - Windows güncellemelerini nasıl "zorlayabilirim"?

Bir hafta sonra "eski" Windows güncellemelerinin olmasını istemiyorum, bu yüzden "bir adımda" yapılabilir mi? Windows'u güncelleştirmeleri denetlemeye ve varsa bunları yüklemeye zorlayan herhangi bir "sihirli" komut var mı?

Bir komut dosyası kullanarak güncellemeleri otomatik olarak kontrol edebilir ve yükleyebilirsiniz. Bu, XP veya Windows 7'de çalışacaktır.

İndirilebilecek bir dizi komut dosyası var, işte benim :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop 

Bunu aşağıdaki gibi komut satırından çalıştırıyorsunuz:

cscript wsusupdate.vbs

Senaryom sadece minimal düzeyde işlevseldir ancak yine de faydalı olabilir. Pek çok ek özelliğe sahip başka tür komut dosyaları da var, bir Google araması deneyin.

Windows Update'i kullanmanın genel yolunun ötesinde, bir komut satırından denetimi zorlayabilirsiniz.

Bir yönetici komut istemi açın ve çalıştırın:

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe, Windows Update'in Otomatik Güncelleştirme İstemcisidir ve Microsoft Update'ten kullanılabilir güncellemeleri (MS Windows platformunun çeşitli sürümleri için) kontrol etmek için kullanılır.

Bu bir yüklemeyi zorlamaz.

Güncellemeleri kontrol etmek için Denetim Masası, Güvenlik, Windows Update'e gidin ve ardından "Güncellemeleri kontrol et" i tıklayın.

Güncellemeler için gerçek bir yeniden taramaya zorlamanın başka bir yolu, % windir% \ Windows \ SoftwareDistribution \ Download : 'da depolanan tüm güncellemeleri silerek listeyi temizlemektir.

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

Sonra Windows Update'e gidin ve "Güncellemeleri kontrol et". Sisteminizdeki her güncellenebilir dosya kontrol edildiğinden bir saat sürebilir (daha sonra "Güncellemeleri kontrol et" hızlı olacaktır). Bu yaklaşım hataları ortadan kaldırır, güncellemeleri durdurur ve en azından MS'nin gördüğü kadar temiz, güncel bir sistem sunar.

yeni windows yüklemesini güncellemek için wuinstall adında ikinci bir parti aracı kullanıyorum . Bununla, otomatik yeniden başlatmalar da dahil olmak üzere tüm güncelleme işlemini otomatikleştirebilirsiniz. Kullanıcı katılımı olmadan güncel bir pencereyi güncellemenin en hızlı yollarından biri olduğunu düşünüyorum.

Windows 7'deki yeni yüklemenizin bir parçası olarak, IE'yi yükselttiyseniz veya henüz IE çalıştırmadıysanız ve tanıtım sorularını cevapladıysanız, Windows Update'in size bir hata vereceğini gördüm. Ayrıca, GUI'den geçmeden Windows Update'i Microsoft Update'e geçirmenin bir yolunu bulamadım, bu yüzden IE'yi manuel olarak ateşledim, başlattım ve ardından GUI üzerinden Windows Update'i ayarlıyorum, böylece Microsoft Update'e geçebilir ve ilk hata. Kilometreniz değişebilir.

Bu yazıdaki adımları takip ederek başarı elde ettim , IE8 ve WI4.5'i yükleyerek , indirmeleri başlatmak için otomatik güncellemeleri tetikleyecektir.