Firefox'u bir komut dosyası aracılığıyla nasıl yapılandırabilirim?

Bir komut dosyası (VBS veya toplu iş) aracılığıyla aşağıdaki Firefox ayarlarını yapılandırmak istiyorum

• Varsayılan anasayfa
• Varsayılan arama motoru
• otomatik güncellemeyi devre dışı bırak

Mümkün mü?

Bunu, tercih ettiğiniz komut dosyası diliyle Mozilla tercih dosyaları oluşturarak veya değiştirerek yapabilirsiniz .

Bu dosyalar aracılığıyla ayarlanabilen tercihlerin bir listesi için, Mozilla Tercihleri ve about: config belgelerine bakın, ancak listenize karşılık gelenler şu şekilde görünecektir:

• browser.startup.homepage (Varsayılan anasayfa)
• browser.search.defaultenginename (Varsayılan arama motoru)
• app.update.auto (otomatik güncellemeyi etkinleştir / devre dışı bırak)

Ancak, ortamınıza bağlı olarak, ayarları özel bir eklenti yoluyla ( Mozilla Tercihleri'nin Kısa Kılavuzu'ndaki XPI yorumlarına bakın ) veya FirefoxADM veya benzeri GPO aracılığıyla ayarları zorlamanız daha iyi olabilir .

Kullanıcı profilleri klasöründeki user.js dosyasındaki özel tarayıcı seçeneklerini geçersiz kılabilirsiniz. Ben sık sık boru hattı gibi bazı seçenekleri geçersiz kılmak için kullanın. Kullanıcıyı güncelledikten sonra Firefox'un yeniden başlatılması gerekiyor. User.js dosyası yoksa bir tane oluşturmanız gerekir.

aradığım cevabın bir kısmını tam anlamıyla kopyalamak / yapıştırmak için (win env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

Ekle

user_pref("browser.startup.homepage", "http://www.URL");

Get-Content / cat string.txt / "String" >> yoluyla uzak makinelere kopyalama girişimlerim prefs.js, dizedeki kaçış karakterleri nedeniyle dosyaya çöp eklenmesiyle sona erdi .

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Konu bir litte eski, ama yine de benim çözüm paylaşmak istiyorum. Umarım bu birine yardımcı olur. Benzer bir sorun yaşadık ve windows store'dan sertifikaları firefox'a eklemek istedik. Bunu yapmak için bir senaryo oluşturdum. Her neyse, ihtiyaçlarınıza göre değiştirebilirsiniz: Sadece cfg_file_name.cfg [...] adresindeki satırları ekleyin veya kaldırın ve örneğin başlangıç ​​sayfası ve benzeri için ihtiyacınız olanı ekleyin . ^ Sondan önce ayarlamayı unutmayın), aksi takdirde çalışmaz! echo pref("browser.startup.homepage", "http://superuser.com"^);

49 sürümünden beri böyle yapabilirsiniz:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit