Nasıl cmd.exe "hangi <binary>"

Hızla ikili %PATH%değişkenin ( değişkenin işaret ettiği) nerede olduğunu belirlemenin bir yolu var mı .

Bu which perlgeleneksel bir unix kabuğundaki karşılığıdır.

Kaynak Kit'in bir wherekomutu olduğunu anlıyorum , ancak bu kit (kurumsal) bilgisayarımda yüklü değil, bu yüzden kullanamıyorum where.

Bir cmd.exe tek astarı which:

for %G in (<binary.exe>) do @echo.%~$PATH:G

Basit bir which.bat olarak kodlayabilirsiniz:

@echo off
for %%G in (%1) do @echo.%%~$PATH:G

EDIT: ikili tam adı gerektirir: which perl.exedeğil which perl. % PATHEXT% değerini dikkate alan bir toplu iş dosyası yazmak mümkündür, bu nedenle ikili dosyanın tam adına ihtiyaç duymaz. İhtiyacınız olursa lütfen bana bildirin.

EDIT2: Yine de toplu iş dosyası yazmaya karar verdim. İşte burada:

@echo off
setlocal enabledelayedexpansion

set ext= ;%PATHEXT%
:extloop1
for /f "delims=; tokens=1,*" %%A in ("!ext!") do (
  if exist %1%%A (
    echo .\%1%%A
    goto finish
  )
  set ext=%%B
)
if "!ext!" neq "" goto extloop1

set ext= ;%PATHEXT%
:extloop2
for /f "delims=; tokens=1,*" %%A in ("!ext!") do (
  for %%C in (%1%%A) do (
    if exist %%~$PATH:C (
      echo %%~$PATH:C
      goto finish
    )
  )
  set ext=%%B
)
if "!ext!" neq "" goto extloop2

:finish
endlocal

İlk olarak, Bob'un önerisine göre, ikili dizinin geçerli dizinde olup olmadığını kontrol eder. İkili bulunmazsa,% PATH% değişkeni üzerinden arama yapan başka bir döngü yürütülür.

Döngüler temel alınır if ... goto, forkomut yalnızca extdeğeri ';' ile ayırmak için kullanılır karakter. Değeri %PATHEXT%ikisi de - tam adlandırılmış ikili aramaya izin veren boş bir uzantısıyla başa eklenmesi which perlve which perl.exeeserleri.

Paul Sadowski'nin yardımcı programlar koleksiyonunu deneyebilirsiniz - bir içerir which. Şuraya bakın: http://www.paulsadowski.com/wsh/cmdprogs.htm