Windows 7'de varsayılan kopya yeniden adlandırma değiştir

Bu sorunun çözümünü Windows 7'de çalışabilmek ancak şimdiye dek şanssız bırakmaya çalışıyorum:

Windows XP varsayılanını değiştirmek için herhangi bir seçenek Kopyala Burada, "{name}. {Ext}" adlı kopyadan "{name}. {Ext} .copy" ye adlandırma

.Cmd dosyasını oluşturarak denedim, ancak tam olarak istediklerimi başaramadım.

Temel sorum varsayalım ki, zaten bir klasörde bir xxx.ext dosyası var. Aynı klasöre, aynı ada sahip bir dosyayı kopyaladığımda, xxx (1) .ext olarak adlandırılır. Bunu xxx_1.ext olarak adlandırmak istiyorum. Bana bunun için bir yol söyleyebilir misiniz?

Bir yerde değiştirdiğim herhangi bir varsayılan ayar var mı?

Windows 7'de tam olarak "xxx (1) .ext" değil. "Dosya Adı.ext", "Dosya Adı - Copy.ext", sonra "Dosya Adı - Kopyala (2) .ext", "Dosya Adı - Kopyala (3) .ext "vb. Bunun yerine "Dosya Adı.ext" in "Dosya Adı_1.ext", "Dosya Adı_2.ext" e kopyalanmasını mı istiyorsunuz? Cmd dosyası buna göre kolayca değiştirilebilir:

for %%f in (%*) do call :try_copy %%f 1
goto :eof

:try_copy
if not exist "%~n1_%2%~x1" goto :copy
call :try_next %1 %2
goto :eof

:copy
copy %1 "%~n1_%2%~x1"
goto :eof

:try_next
if "%2" == "" ( set _next=1 ) else ( set /a _next=%2 + 1 )
call :try_copy %1 %_next%
goto :eof

Düzenleme: Aşağıdaki tartışmalara göre, dosyaları belirli bir klasöre kopyalamak ve sırayla yeniden adlandırmak için değiştirilmiş toplu iş dosyası:

REM Specify your destination path below without quotes or trailing backslash
set folder=I:\New folder

for %%f in (%*) do call :try_copy %%f 1
goto :eof

:try_copy
if not exist "%folder%\%~n1_%2%~x1" goto :copy
call :try_next %1 %2
goto :eof

:copy
copy %1 "%folder%\%~n1_%2%~x1"
goto :eof

:try_next
if "%2" == "" ( set _next=1 ) else ( set /a _next=%2 + 1 )
call :try_copy %1 %_next%
goto :eof