Outlook2010'da, şu anda erteleyen hatırlatıcıları görüntülemenin bir yolu var mı?

Outlook 2010'da şu anda ertelenen öğelerin bir listesini almanın herhangi bir yolu var mı? Örneğin, diyelim ki iki hafta sonra ertesi Pazartesi önemli bir öğle yemeği toplantısı için Cuma günü bir hatırlatma ayarladım (hafta sonu öncesinde Pazartesi görevlerini hatırlatmak istiyorum). Hatırlatma Cuma günü açıldığında, Pazartesi günü öğle yemeğinden hemen önce tekrar görünmesi için üç gün erteliyorum. Sonra Pazartesi dolaşıyor ve hafızam bulanık ve ben doğru bir şekilde erteleme yerine hatırlatma yanlışlıkla Cuma günü reddetti biraz paranoyak. Yine de takvimimdeki orijinal randevuyu görebiliyorum, ancak toplantıyı kaçırmamam için hatırlatıcıyı beklediğimde gerçekten açacağımdan emin olmalıyım.

Outlook 2010'da şu anda ertelenen hatırlatıcıların bir listesini çıkarmanın herhangi bir yolu var mı? Bu, hatırlatıcısını daha sonra ertelediğim bir görevi tamamladığım ve şimdi ertelenmiş hatırlatıcıyı kaldırıp iptal etmek istediğim durumlar için de yararlı olacaktır.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

VBA'ya aşina değilseniz, Slipstick'in açıklama sayfasına bakın . Aşağıdakiler hakkında bilgi bulacaksınız:

• makro güvenlik ayarları;
• kodu nereye koyacağınız (Insert | Module ile normal bir modül kullanabilirsiniz); ve
• nasıl düğme oluşturulacağı.

Bu ertelenmiş ürün forumu yazısına göre, ertelenmiş öğelerin bir listesini görmek mümkün değildir. Gönderi, bazı hatırlatma alanlarını görüntüleyen özel bir görünüm oluşturarak sınırlı miktarda yararlı bilgi görebileceğinizi gösteriyor.

Takvim sekmesini tıklamayı deneyin, Görünümü Görüntüle ve Değiştir'i seçin. Ardından Liste'yi seçin. Bu, tüm hatırlatıcıların bir listesini gösterir.