Yeni bir sürüm çıktığında Flash Player'ı otomatik olarak nasıl güncelleyebilirim?

Özet:

Flash Player, Güncelleştirme Hizmeti güvenilir bir planla çalıştırılmasını etmez ve otomatik olarak indirebilir ve ne zaman güncelleştirmeler geçerli değildir gelmez çalıştırın.

Flash Player'ın güncel bir sürümünün (Chrome'u yerleşik oynatıcıyla kullanmayanlarımız için) yüklü olmasının önemi göz önüne alındığında, yeni güncellemelerin hemen tespit edilmesini sağlamak için bir yol bulmak istiyorum ve yüklü.

Aşağıdakiler, bu sorunu kendi başıma çözme çabalarımın detayları ...

Ek A: Flash Player Güncelleme Hizmeti

Tamam, Flash Player 11.2'de (ya da öylesine?) Adobe Flash Player Güncelleme Hizmeti'ni (FlashPlayerUpdateService.exe) ekledi , Flash Player'ı güncel tutması gerekiyordu ...

• Kurulumun ardından FPUS, Başlangıç ​​Türü Manuel olarak ayarlanmış bir Windows Hizmeti olarak çalışacak şekilde yapılandırılmıştır.

• Bu hizmeti her saat başlatmak için Zamanlanmış Görev (Adobe Flash Player Updater.job) eklenir.

Şimdiye kadar, çok iyi - bu kurulum sürekli çalışan bir hizmete sahip olmaktan kaçınır, ancak kontrollerin herhangi bir güncellemeyi hızlı bir şekilde yakalamak için yeterince sık çalıştırılmasını sağlar. Google'ın yazılım güncelleyicisi benzer bir şekilde yapılandırılmıştır ve bu iyi çalışır ...

... Ve yine de, yüklü Flash Player'ımın sürümünü kontrol ettiğimde , 11.6.602.180 olduğunu buldum , ki bu dosyaların zaman damgalarına bakarak 12 Mart Salı günü C:\Windows\System32\Macromed\Flashen son güncellendi (veya yüklendi) , 2013 - 3/12/13, 05:0:08 .

Bu gözlemi 25 Nisan 2013 Perşembe - 25.04.2013, 19: 00: 00'da yaptım ve Adobe'nin web sitesini kontrol ettikten sonra Flash Player'ın mevcut sürümünün 11.7.700.169 olduğunu buldum .

Son güncellemeden bu yana bir aydan fazla bir süre geçti, web sitesinde açıkça yeni bir tane var, ancak makinemde saatlik kontrolün bunu fark ettiğini veya indirmeye niyeti olmadığını belirten bir gösterge yok .

Ek B: Flash Player güncelleyiciyi manuel olarak çalıştırma

Bir zamanlar, koşmak size Yükle düğmeli bir pencere verecektir ; üzerine basmak, geçerli sürüm için yükleyiciyi indirir (otomatik olarak, bir tarayıcı açmadan) ve çalıştırırsa, o yükleyiciyi tıklar ve tamamlanırsınız. Manuel, ama işe yaradı! Mevcut kurulumumu güncel değil (bkz. Ek A), önce bu manuel güncelleme işlemini denedim. Ancak...FlashUtil32_<version>_Plugin.exe -update plugin

• Çalışıyor (benim durumumda ) ... sadece İndir düğmeli bir pencere sunar, İndir düğmesini tıklamak tarayıcımı https://get3.adobe.com/flashplayer/update/activex URL'sine açar .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• Çalışıyor (benim durumumda ) ... yalnızca İndir düğmeli bir pencere görüntüler, İndir düğmesini tıkladığınızda tarayıcım https://get3.adobe.com/flashplayer/update/plugin URL'sine açılır .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Bana gönderdiği İndirme sayfasına devam edebilir , foistware kutusunun işaretini kaldırabilirim ("Ücretsiz! McAfee Security Scan Plus"), bu yükleyiciyi indirin (ActiveX, foistware yok: install_flashplayer11x32axau_mssd_aih.exe, Eklenti, foistware yok: install_flashplayer11x32au_mssd_aih.exe) & muhtemelen güncellenmiş bir Flash'ım var ... ancak başka bir exe'yi manuel olarak indirip çalıştırmam gerekirse Flash Player Güncelleme Hizmeti'nin amacı nedir?

son söz

O zamandan beri güncelleme hizmetinin kasıtlı olarak manuel olarak indirme sayfasını erken benimseyenlere yönlendirildiğinden şüpheleniyorum. Eğer bu doğruysa, kendi güncelleyicimi yazmanın bu kadar kısa bir çözümü yoktur; umarım yanılıyorum.

Belki de güncelleyici sadece 11.6.x aralığındaki güncellemeleri uyguluyor?

Her zaman daha güvenilir olduğunu düşündüğüm yükleyicilere doğrudan bağlantılar kullanabilirsiniz: ActiveX ; Eklenti .

Bu .bat dosyasıyla Internet Explorer, Firefox (SeaMonkey vb.), Chromium tabanlı (Chrome, Opera 15+ vb.) İçin flash player'ı otomatik olarak güncellemeyi veya yüklemeyi deneyecektir :

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Gerekli indirebilirsiniz wget burada ve .bat yerleştirildi nereye aynı dizine koydu gerekmez.

Autoit'te yazılmış biraz daha gelişmiş bir örnek .

Özellikler: Yeni sürüm için basit kontrol, burada yeni sürüm yoksa flash player yükleyici indirmeden programdan çıkın. İndirme yükleyicisi başarısız olursa, mesaj kutusunu hata ile göster ve çık. Gizli komut istemi penceresi. Uyanmaya gerek yok.

Autoit ve Editor'ü yükledikten sonra . Masaüstünde sağ tıklayın-> Yeni-> Otomatik Komut Dosyası. Bu oluşturulan dosyaya sağ tıklayın-> Düzenle. Şimdi ScITE penceresini görmelisiniz ve "Kodunuzu buraya ekleyin" satırından sonra şu kodu ekleyin:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Ardından SciTE penceresinde Tools-> Build veya F7 tuşuna basın. Şimdi Autoit betiği olan aynı dizinde bağımsız yürütülebilir.

Bu "güncelleyici" için yeni klasör (yazma erişim izni ile) yapmanızı öneririm. Başlamak için bu "güncelleyiciye" kısayol da ekleyebilirsiniz .

İşte kaldırma flash player için uygulama.

Sadece, toplu betiğimi sizinle paylaşmak istiyorum, bu kod parçasını not defterinize kaydedin ve Download_Install_Last_Flash_Player.bat olarak adlandırın

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************