Belirli bir pencere boyutuna sahip bir konsol uygulamasını nasıl açabilirim?

Başlatmak istediğim uygulama MongoDB. Ben normal olarak başlar, şöyle görünüyor:

Satır sonlarını sevmiyorum ve çok fazla ekran alanım var, bu yüzden satır sonlarından kurtulmak için adı geçen alanı kullanmak istiyorum.

Konsol penceresinin boyutunu değiştirebilirim MODE, bu yüzden böyle bir toplu iş dosyası yazdım:

@ECHO OFF
MODE con:cols=140 lines=70
%~dp0mongodb\bin\mongod --dbpath %~dp0data --rest

Çok uzak çok iyi. Bu toplu iş dosyasını başlattığımda, istediğiniz gibi daha büyük bir pencere alıyorum.

Ama şimdi MongoDB'den çıkmak için Ctrl+ tuşuna Cbastığımda can sıkıcı istemi alıyorum:

Terminate batch job (Y/N)?

Bu işe yaramaz, çünkü yeni çıkmış olduğum komut zaten toplu işteki son komuttu ve ne cevap versem de sonuç aynı.

Peki, Ctrl+ 'ya bastığımda bu istemi almadan uygulama için daha büyük bir konsol penceresi nasıl alabilirim C?

Bugün başka bir konsol uygulamasını kapatabilecek ve konsol ana bilgisayarının pencere boyutunu ayarlayabilecek küçük bir C # uygulaması uygulamak için birkaç saat geçirdim .

console-wrapperkullanımı kolaydır. Yalnızca birkaç komut satırı parametresi bekler:

Usage: console-wrapper.exe [OPTIONS]

Options:

      --subject=VALUE        The application that should be started by the
                               console wrapper.
      --width=VALUE          The desired width of the console window.
      --height=VALUE         The desired height of the console window.
  -h, -?, --help             Shows this help message

--widthve --heightortaya çıkan konsol penceresinin boyutunu ayarlamak için kullanılır. --subjectisteğe bağlı olarak kullanılabilir, atlanırsa, kalan parametreler başlatılacak komut (parametrelerle) olarak kabul edilir.

Şimdi başlangıç ​​betiğimizde kullandığım son çağrı:

START "MongoDB" database\console-wrapper.exe --width=140 --height=70 %~dp0database\mongodb\bin\mongod.exe --dbpath %~dp0database\data --rest

Ortaya çıkan pencere istenen boyuta sahip olacak ve Ctrl+ Ctuşuna basıldığında pencere kapanacaktır (içerilen işlemi düzgün bir şekilde kapattıktan sonra).

Bir powershell betiğinden çalıştırmayı düşündünüz mü? Powershell kendi penceresini yeniden boyutlandırabilir

$h = Get-Host
$buf = $h.UI.RawUI.BufferSize
$buf.Width = 300
$h.ui.rawui.BufferSize = $buf
$win = $h.UI.RawUI.WindowSize
$win.Width = 150
$h.ui.rawui.WindowSize = $win
#Command to start mongodb here.

Bu, 150 boyutunda bir pencere oluşturur, ancak aynı zamanda 300'e doğru kaydırılabilir bir arabellek içerir.

Soruyu anladığım kadarıyla, MongoDB'nin belirtilen konsol penceresi boyutuna sahip olmasını ve Ctrl+ tuşuna bastığınızda çıkmasını istiyorsunuz C. O zaman cevap oldukça basittir: başlatmak için kısayolu kullanın.

Ben yok mongodkullandığım bu yüzden, çalıştırılabilir perl.exebir örnek olarak. Çalıştır iletişim kutusundan ( Windows+ R) başlattığınızda , konsol penceresinin boyutu 300 satır için arabellek boyutuyla standart 80 × 25 olur.

1. mongod(Veya perlbenim durumumda) için bir kısayol oluşturun .
2. Kısayola sağ tıklayın ve Özellikler'e tıklayın .
   1. On Kısayol sekmesini Hedef alanında, parametreleri eklemek mongod.
   2. Başlama alanı, başlatılan programın ilk geçerli dizinini denetler. Varsayılan olarak .exe'nin bulunduğu dizin olacaktır.
3. Click Düzen sekmesini.
   1. Değişim Pencere boyutu 140 x 70.
      
   2. Sen artırabilir Yükseklik ait Ekran tampon boyutu eski iletilere yukarı edebilmek için 1000 veya daha fazla.
   3. Sistem konumu bırak penceresini temizlerseniz , konsol penceresinin ekrandaki konumunu belirleyebilirsiniz.
4. Kısayol özelliklerini kapatmak için Tamam'ı tıklatın .

Şimdi bu kısayolu tıklattığınızda, konsol penceresi belirtilen boyutta olacaktır. Ctrl+ CDüğmesine bastığınızda , uygulamadan çıkılır ve ek bilgi istemeden pencere kapanır.

Pencereyi başlattıktan sonra Çalıştır iletişim kutusundan da değiştirebilirsiniz . Konsol penceresinin başlığına sağ tıklayın ve Özellikler'e tıklayın . Click Düzen , sekmesini pencere boyutunu ayarlamak ve tıklayın OK özelliklerini kapatmak ve hemen değişiklikleri uygulamak için. (Pencere kısayoldan başlatıldıysa, kısayolun özellikleri güncellenir.)

Aynı uygulamayı bir sonraki başlatışınızda, konsol penceresinin boyutu sihirli olarak aynı boyutta olacaktır. (Bu sefer kontrol etmedim ama işe yaradı.)

Varsayılan konsol düzeni ayarları burada kayıt defterinde yaşar:

[HKEY_CURRENT_USER\Console]

Bu ayarları değiştirebilirsiniz; bunlar, yola bakılmaksızın başlatılan TÜM komut pencerelerine uygulanır. Ne yazık ki, ham değerler insan dostu değildir.

Onları istediğiniz şekilde ayarlamak için, normal bir cmd penceresi açın, ardından ayarları istediğiniz gibi düzenleyin. Yukarıdaki yolda kayıt defterine bakın ve cmd.exe için "Konsol" altında bir alt anahtar görmelisiniz. Bu anahtarı bir dosyaya aktarın, yukarıdakinin yolunu değiştirin ve içe aktarın veya değerleri birinden diğerine manuel olarak kopyalayın. Daha sonra cmd.exe'ye özgü girişi silebilirsiniz. Şimdi, açılan tüm komut pencereleri değiştirilen varsayılanları kullanacaktır.

Ben ilk kez RDP zaman kolayca onları yeni bir sunucuya pop böylece standart varsayılanları ile birkaç kayıt defteri giriş dosyaları oluşturmak için kullanışlı buldum. Normalde kullandığım iki boyut için ön ayarlar yaptım.

1024 x 768 için (Bunu normalde çok oturumlu bir RDP aracıyla erişilen sunucular için kullanırım):

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:012c0050
"WindowSize"=dword:00190050
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

1280 x 1024 için:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:0bb800af
"WindowSize"=dword:004b00af
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

StartKomutu mongodb çağrısının önüne koy . Bunu düzeltmesi gerektiğine inanıyorum.

Bir toplu iş dosyasını birkaç küçük yardımcı programla birlikte çalıştırmaktan memnunsanız, burada tam bir çözüm benim tarafımdan gönderilir:
Bir toplu iş dosyası bir programı nasıl çalıştırabilir ve pencerenin konumunu ve boyutunu nasıl ayarlayabilir?

Içindekiler aşağıdaki gibi. . . .

Bu demo toplu iş dosyası bir komut satırı programı çalıştıracak ve Komut İstemi konsol penceresinin konumunu ve boyutunu ayarlayacaktır. Bu toplu işin genel teması, önceki iki çözümle aynıdır (yukarıdaki bağlantıdaki Yığın Taşması sayfasında), ancak bu işi yapmak için bazı benzersiz sorunlar ve geçici çözümler vardı - bu, 'CMD tarafından barındırılan bir Komut İstemi penceresi .EXE 'değil,' EXPLORER.EXE 'gibi bir GUI penceresi değil.

Daha fazla bilgi için toplu iş dosyasındaki tüm yorumları ve açıklamayı okuyun.

Kullanılan araçlar:
1.   MonitorInfoView  Nir Sofer'e tarafından (41 KB)
2.   NirCmd  Nir Sofer'e tarafından (43 KB)
3.   GetPIDs  Daniel Scheibli ile (280 KB)
4.   UPX.EXE  --- bu demo için kullanacağı komut satırı programı; toplu iş dosyasıyla aynı dizine yerleştirin.
5. Bir toplu iş dosyası --- aşağıya bakın

Beş dosyayı da bir dizinde toplayın. Bu, herhangi bir Windows sisteminde çalışmaya hazır toplu iş dosyasıdır.

Bu demo toplu işin size özel konsol penceresi sunmanın yanı upx.exesıra, komut satırı anahtarlarıyla çalışması da--best -v -o getpids-compressed.exe getpids.exe. 'GetPID'ler' aracımızı 88 KB'ye kadar sıkıştıracağız ........ Başlattıktan sonra ilginç bir fenomen görmek için bu konsol penceresinin başlık çubuğuna çift tıklayın; bu konsol penceresi GUI gibi davranıyor!

@echo off
setlocal enabledelayedexpansion enableextensions
pushd %~dp0%

REM ----- ADD SOME USEFUL INFORMATION TO THIS CONSOLE WINDOW TITLE.
for /f "tokens=3" %%A in ('getpids.exe') do set _PROCESS_ID_=%%A
title This batch file runs a command-line program and sets the position and size of its console window        (PROCESS ID = %_PROCESS_ID_%)

REM ********************** DESCRIPTION ************************************
REM ** This script opens a command-line program console window with specified
REM ** screen properties at the primary monitor (containing the taskbar).
REM ** The "X/Y position" and "W/H size" of the console window is auto-set by
REM ** this script and the monitor resolution is auto-calculated to suit.
REM ** 'MonitorInfoView.exe' is the helper tool used to capture the resolution
REM ** info of the monitor.
REM ** 'nircmd.exe' is the tool performing all the display trickery.
REM ** 'getpids.exe' is the helper tool used to capture the Process ID of the
REM ** working batch file, thus allowing us to identify which CMD.EXE host this
REM ** console window belongs to when looking at Task Manager.
REM **
REM ** To tweak this script, go to the code section named:
REM ** >>>>> USER INPUT/PREFERENCES ARE ALL SET HERE <<<<<
REM ***********************************************************************

REM ----- CLEAR ANY PREVIOUS JOB OUTPUTS IF THEY EXIST
if exist ~TMP.TXT type NUL > ~TMP.TXT

REM ----- OUTPUT THE PRIMARY MONITOR INFORMATION TO A TEXT FILE
MonitorInfoView.exe /hideinactivemonitors 1 /stext ~TMP.TXT

REM ----- ISOLATE THE RESOLUTION LINE, REMOVING ALL THE OTHER LINES IN THE TEXT FILE
for /f "delims=" %%A in ('type "~TMP.TXT" ^|find.exe /i "Maximum Resolution"') do echo %%A>~TMP.TXT

REM ----- GET THE RESOLUTION NUMBERS, AND SET THEM AS VARIABLES
for /f "tokens=3,4 delims=:X " %%A in ('type "~TMP.TXT"') do set _SCREENW_=%%A& set _SCREENH_=%%B


REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [BEGIN] <<<<<<<<<<<<

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  FILE NAME (WITH EXTENSION)
REM ----- |
REM ----- | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR)
REM ----- | |ALSO READ THE NEXT COMMENTS ABOUT SETTING SWITCHES   

    set _MYPROGRAM_=upx.exe

REM ----- ----------------------------------------   
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  SWITCHES (TO BE PASSED TO THE PROGRAM)
REM ----- |
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF RUNNING THE PROG WITHOUT ANY PARAMETERS
REM ----- | | 
REM ----- | | |IF THE VALUE CONTAINS THE CHARS  '|'  OR  '<'  OR  '>'  THIS BATCH WILL FAIL TO RUN !!!
REM ----- | | |
REM ----- | | | |YOU CAN APPEND EXTRA TEXT TO THE END OF THE COMMAND BY USING THE AMPERSAND CHARACTER '&'
REM ----- | | | | EXAMPLES:
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4 & this text will be ignored; useful for adding some inline comments.
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4         & this works too, and the extra blank spaces will also be ignored.
REM ----- | | | | 
REM ----- | | | | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR), PATH ARGUMENTS MUST POINT TO A SPECIFIC LOCATION
REM ----- | | | | |AND BE ABSOLUTE OR INCLUDE ENVIRONMENT VARIABLES, AND ALWAYS ENCLOSE PATHS IN QUOTES.
REM ----- | | | | | EXAMPLES:
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type %0                                       <<<<<<<this batch file (quotes are optional; the only exception to the rule)
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\File.txt"                     <<<<<<<goes back one Dir from this batch file
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\SomeFolder\File.txt"          <<<<<<<goes back one Dir from this batch file and then forwards into "SomeFolder"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4          <<<<<<<displays directory listing of the System folder. NOTE: 'dir' by itself and
REM ----- | | | | |                                                                                without a specific path argument will resolve to the folder of this batch file.

    set _MYPROGRAMSWITCHES_=--best -v -o getpids-compressed.exe getpids.exe      &// original is 280 KB, will compress down to 88 KB

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  DIRECTORY PATH (OF THE PROGRAM)
REM ----- | 
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF THE PROG IS AT SAME LOCATION AS BATCH
REM ----- | |THIS VARIABLE WILL BE IGNORED IF THE PROG IS 'CMD.EXE'
REM ----- | | 
REM ----- | | EXAMPLES:
REM ----- | | set _MYPROGRAMDIR_=.\                               <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  dot backslash *OR* dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%                            <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  same locatiion as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=..\                              <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  dot dot backslash *OR* dot dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%\..                         <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  same as location as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=%SYSTEMROOT%\..\My Utilities     <<<<<<<relative path, program is back one directory from the Windows folder
REM ----- | |                                                                  and then forwards into the folder 'My Utilities'
REM ----- | | set _MYPROGRAMDIR_=C:\My Utilities\                 <<<<<<<absolute path, enclosing quotes are optional; trailing backslash is optional
REM ----- | |                                                                  same location as previous

    set _MYPROGRAMDIR_=

REM ----- ----------------------------------------
REM ----- |SET THE WANTED DIMENSIONS OF THIS CONSOLE WINDOW

    set /a _WINW_=(%_SCREENW_% / 2) + 250
    set /a _WINH_=(%_SCREENH_% / 2) + 150
    set /a _WINX_=(%_SCREENW_% - %_WINW_%) / 2
    set /a _WINY_=(%_SCREENH_% - %_WINH_%) / 2

REM ----- ----------------------------------------
REM ----- |STYLE THIS CONSOLE WINDOW   !!!IMPORTANT!!!
REM ----- |
REM ----- | |IF WE DO NOT USE THE 'MODE' COMMAND HERE ALONG WITH ITS 'COLS/LINES' VALUES THEN
REM ----- | |THE POSITIONING/SIZING OF THIS WINDOW BY 'NIRCMD.EXE' FURTHER DOWN WILL NOT WORK !!!
REM ----- | |
REM ----- | | |SOME COMMANDS WILL OUTPUT A LOT OF LINES AND AND THE CONSOLE DISPLAY WILL BE TRUNCATED
REM ----- | | |RUN THIS FOR AN EXAMPLE=====>   cmd.exe dir "%systemroot%\system32" /a/o/s/4   <=====
REM ----- | | |TO SOLVE THIS PROBLEM, SET THE 'LINES' VALUE OF 'MODE' TO A VERY HIGH NUMBER
REM ----- | | |THE MAXIMUM NUMBER IS 32000 (ON MY SYSTEM); 'MODE' WILL BE IGNORED IF THE NUMBER IS HIGHER !!!   

    color 0A
    mode.com con:cols=%_SCREENW_% lines=10000

REM ----- ----------------------------------------
REM ----- |DELETE THE TEMP TEXT FILE MADE BY 'MonitorInfoView.exe'
REM ----- |COMMENT OUT THE LINE IF YOU DON'T CARE ABOUT DELETING IT

    del /f /q ~TMP.TXT 2>nul >nul

REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [END] <<<<<<<<<<<<<<
REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


REM ----- RUN THE TASK . . .
nircmd.exe win setsize foreground %_WINX_% %_WINY_% %_WINW_% %_WINH_%
popd

if not defined _MYPROGRAMDIR_ set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == "." set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == ".\" set _MYPROGRAMDIR_=%~dp0
pushd %_MYPROGRAMDIR_%
if not exist %_MYPROGRAMDIR_% goto _SKIP_
set _CONVERT_PATH_="%CD%"
set _CONVERT_PATH_=%_CONVERT_PATH_:"=%
set _MYPROGRAMDIR_=%_CONVERT_PATH_%
:_SKIP_
popd

echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
if "!_MYPROGRAM_!"=="cmd.exe" (echo PROGRAM DIR ..........: %SYSTEMROOT%\system32) else (echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!)
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================

if "!_MYPROGRAM_!"=="cmd.exe" (goto _PROGRAM_IS_CMD_) else (goto _PROGRAM_IS_OTHER_)

:_PROGRAM_IS_CMD_
cd /d "%SYSTEMROOT%\system32"
!_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_PROGRAM_IS_OTHER_ 
cd /d "!_MYPROGRAMDIR_!"
if "%CD%\!_MYPROGRAM_!" == "%CD%\" goto _ERRORMESSAGE_
if not exist "%CD%\!_MYPROGRAM_!" goto _ERRORMESSAGE_
"!_MYPROGRAMDIR_!\!_MYPROGRAM_!" !_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_ERRORMESSAGE_
cls
color 4F
echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================
echo                        ^^!^^!^^!  E R R O R  ^^!^^!^^!
echo.
echo The program has failed to run; the path set by the above values does not exist.
echo Please exit this window and check the values you have set in this batch file.
echo.
echo This batch file is located here:
echo %0
echo. & echo. & echo. & echo. & echo.

:_END_

REM ----- CLEAR VARIABLE VALUES FROM MEMORY . . .
set _PROCESS_ID_=
set _SCREENW_=
set _SCREENH_=
set _MYPROGRAM_=
set _MYPROGRAMSWITCHES_=
set _MYPROGRAMDIR_=
set _WINW_=
set _WINH_=
set _WINX_=
set _WINY_=
set _CONVERT_PATH_=

REM ----- STOP THIS CONSOLE WINDOW FROM CLOSING   !!!IMPORTANT!!! . . .
REM ----- |
REM ----- | http://superuser.com/questions/306167/how-to-prevent-the-command-prompt-from-closing-after-execution
REM ----- | | by 'kitsu.eb' (April 26, 2014)
REM ----- | | | "My solution (just tested on Win7) is to add CMD as the last line in the batch file.
REM ----- | | |  This runs a nested command prompt that inherits the environment of its parent.
REM ----- | | |  That child shell holds the batch process open until you EXIT, at which point the
REM ----- | | |  batch has no child processes and also exits."
REM ----- | Comment . . .
REM ----- | | by me
REM ----- | | | "This is a workaround. You can't use PAUSE as the last command to stop this window from closing
REM ----- | | |  because the window will terminate after you press a key. While this batch is running, if you open
REM ----- | | |  Task Manager/Process Hacker/Process Explorer you will see an extra CMD.EXE child process running
REM ----- | | |  under the parent CMD.EXE of this batch file."
cmd.exe