Toplu iş dosyasından altyordamdan çık

Bir alt programın içinden bir toplu iş dosyasından nasıl çıkabilirim?

EXIT komutunu kullanırsam, alt rutini çağırdığım satıra dönüp yürütme devam eder.

İşte bir örnek:

@echo off
ECHO Quitting...
CALL :QUIT
ECHO Still here!
GOTO END

:QUIT
EXIT /B 1

:END
EXIT /B 0

Çıktı:

Quitting...
Still here!

Güncelleme:

Bu doğru bir cevap değil, ama sonunda şu şeyleri yaptım:

@echo off
CALL :SUBROUTINE_WITH_ERROR || GOTO HANDLE_FAIL
ECHO You shouldn't see this!
GOTO END

:SUBROUTINE_WITH_ERROR
ECHO Simulating failure...
EXIT /B 1

:HANDLE_FAIL
ECHO FAILURE!
EXIT /B 1

:END
ECHO NORMAL EXIT!
EXIT /B 0

Çift borulu ifadesi:

CALL :SUBROUTINE_WITH_ERROR || GOTO HANDLE_FAIL

kısaltması:

CALL :SUBROUTINE_WITH_ERROR 
IF ERRORLEVEL 1 GOTO HANDLE_FAIL    

Hâlâ CALLER'in durumu ele alması yerine doğrudan bir altyordamdan çıkmanın bir yolu olup olmadığını bilmek isterim, ancak bu en azından işi hallediyor.

Güncelleme # 2: Yukarıdaki şekilde çağrılan başka bir altyordam içinden bir altyordam çağırırken, böylelikle altyordamlar içinden çağırıyorum:

CALL :SUBROUTINE_WITH_ERROR || EXIT /B 1

Bu şekilde, hata, "ana" ye kadar yayılır. Toplu işin ana kısmı hatayı hata işleyicisi GOTO: FAILURE ile işleyebilir

Bunu toplu iş dosyanızın üstüne ekleyin:

@ECHO OFF
SETLOCAL

IF "%selfWrapped%"=="" (
  REM this is necessary so that we can use "exit" to terminate the batch file,
  REM and all subroutines, but not the original cmd.exe
  SET selfWrapped=true
  %ComSpec% /s /c ""%~0" %*"
  GOTO :EOF
)

Ardından şunları arayabilirsiniz:

• EXIT [errorLevel] tüm dosyadan çıkmak istiyorsanız
• EXIT /B [errorLevel] geçerli altyordamdan çıkmak için
• GOTO :EOF geçerli altyordamdan çıkmak için

Bu küçük ayarlamaya ne dersiniz?

@echo off
ECHO Quitting...
CALL :QUIT
:: The QUIT subroutine might have set the error code so let's take a look.
IF ERRORLEVEL 1 GOTO :EOF
ECHO Still here!
GOTO END

:QUIT
EXIT /B 1

:END
EXIT /B 0

Çıktı:

Quitting...

Teknik olarak bu, altyordam içinden çıkmaz. Aksine, altyordamın sonucunu kontrol eder ve oradan harekete geçer.

Yordamdan geri dönmek istemiyorsanız kullanmayın call: kullanın goto.

@echo off
ECHO Quitting...
GOTO :QUIT
ECHO Will never be there!
GOTO END

:QUIT
EXIT /B 1

:END
EXIT /B 0

Toplu iş dosyalarıma hata işleme koydum. Bunun gibi hata işleyicilerini arayabilirsiniz:

CALL :WARNING "This is" "an important" "warning."

Ve işte toplu iş dosyasının sonu:

::-------------------------------------------------------------------
::  Decisions
::-------------------------------------------------------------------
:INFO
IF "_DEBUG"=="true" (
  ECHO INFO: %~1
  IF NOT "%~2"=="" ECHO          %~2
  IF NOT "%~3"=="" ECHO          %~3
)
EXIT /B 0
:WARNING
ECHO WARNING: %~1
IF NOT "%~2"=="" ECHO          %~2
IF NOT "%~3"=="" ECHO          %~3
EXIT /B 0
:FAILURE
ECHO FAILURE: %~1
IF NOT "%~2"=="" ECHO          %~2
IF NOT "%~3"=="" ECHO          %~3
pause>nul
:END
ECHO Closing Server.bat script
FOR /l %%a in (5,-1,1) do (TITLE %TITLETEXT% -- closing in %%as&PING.exe -n 2 -w 1 127.0.0.1>nul)

Bu, geçerli bağlamdan ve bir üst bağlamdan çıkar (yani, bir callderin altyordam betiğinin içinde yürütüldüğünde çıkacaktır):

(goto) 2>nul || exit /b

Veya, hata seviyesi 0'a ihtiyacınız varsa:

(goto) 2>nul || (
    type nul>nul
    exit /b
)

Temel olarak, (goto) 2>nulhata seviyesini 1 olarak ayarlar (hata çıkmadan), üst bağlamda çift boru yürütüldükten sonra yürütmeyi üst bağlama ve koda döndürür. type nul>nulhata seviyesini 0 olarak ayarlar.

UPD:

Yürütmeyi art arda iki kereden fazla geri döndürmek için, birkaçını şöyle zincirleyin (goto) 2>nul ||:

(goto) 2>nul || (goto) 2>nul || (goto) 2>nul || (
    type nul>nul
    exit /b
)

Bağlamı değişken sayıda döndürmek için özyinelemeli bir alt yordam şunlardır:

:Kill
(goto) 2>nul || (
    set /a depth=%1-1
    if %1 GEQ 1 (
        call:Kill !depth!
    )
    (goto) 2>nul || (type nul>nul)
)

Özyinelemeli bir işlevden çağrıldığında:

@echo off
setlocal EnableDelayedExpansion
call:Recurs 5
echo This won't be printed
exit /b

:Recurs
set /a ri+=1
echo %ri%
if %ri% LSS %1 (
    call:Recurs %1
)
echo This will be printed only once
call:Kill %1
exit /b

çıktı:

1
2
3
4
5
This will be printed only once