Kaynak dizideki sütun değerine göre diziyi döndür

Belirli ölçütleri karşılayan yalnızca bir dizi değer elde etmeye çalışıyorum.

Bu kriterlerin karşılanmasının her giriş için bir DOĞRU / YANLIŞ sütununda özetlendiği bir dizilim var.

INDEX MEETS_CRITERIA
1     TRUE
2     TRUE
3     FALSE
4     FALSE
5     FALSE
6     TRUE
7     TRUE
8     TRUE
9     FALSE
10    FALSE

Ayrı bir sayfada, aşağıdaki gibi "MEETS_CRITERIA" sütununda doğru olan tüm indekslerin boşluksuz bir listesini elde etmek istiyorum.

INDEX
1
2
6
7
8

Bunu aşağıdaki dizi formülü ile deniyorum:

{=INDEX(ORIGINAL_ARRAY!$A$2:$A$10, MATCH("TRUE",ORIGINAL_ARRAY!$B$2:$B$10, 0))}

Ancak bu, # N / A döndürür.

Formülümdeki veya yaklaşımımdaki hata nedir?

Clif tarafından yapılan gözlemlerin yanı sıra, şu andaki formülünüz verdiğiniz listeyi değil, sadece tek bir dönüş sağlamak için uygun olacaktır.

Bunun için isteyeceksiniz (Excel 2010 veya üstü olduğunu varsayarsak):

=INDEX(ORIGINAL_ARRAY!$A:$A,AGGREGATE(15,6,ROW(ORIGINAL_ARRAY!$B$2:$B$10)/ORIGINAL_ARRAY!$B$2:$B$10,ROWS($1:1)))

ve kopyalandı.

Öyleyse, hataları maskeleme ile ilgili olarak, verdiğiniz örneğin asıl kurulumunuzu temsil ettiğini varsayarsak - kaynak verilerde sadece bir düzine satır olduğu için - aksi halde verimsiz bir IFERROR kurulumu, yani

=IFERROR(INDEX(ORIGINAL_ARRAY!$A:$A,AGGREGATE(15,6,ROW(ORIGINAL_ARRAY!$B$2:$B$10)/ORIGINAL_ARRAY!$B$2:$B$10,ROWS($1:1))),"")

Söz konusu veri aralığı aslında oldukça büyükse, sayfa başına bir yerde ek bir hücre kullanılması, örneğin, beklenen geri dönüş sayısını belirlemek için tek bir formülün kullanıldığı, örneğin:

=COUNTIF(ORIGINAL_ARRAY!B2:B10,TRUE)

bu daha sonra ana formülde belirtilebilir:

=IF(ROWS($1:1)>D$1,"",INDEX(ORIGINAL_ARRAY!$A:$A,AGGREGATE(15,6,ROW(ORIGINAL_ARRAY!$B$2:$B$10)/ORIGINAL_ARRAY!$B$2:$B$10,ROWS($1:1))))

ve burada açıklanan nedenlerden dolayı IFERROR kurulumundan çok daha verimli olacaktır:

Bir listede bir değer aramak ve TÜM birden fazla ilgili değerleri döndürmek

Saygılarımızla