B kullanıcı kimliği için col B'deki Toplam Benzersiz öğeleri

Google’ın önerdiği, düşündüğüm her şeyi denedim, kopyalamak ve yapıştırmak için buraya kopyalayıp yapıştırın, ancak basitçe ekleyin. Kimlik olarak "id-1" yazan bir metin dizim var. Satırda da bu benzersiz kimliğe sahip olan bir sütundaki benzersiz öğelerin sayısını saymaya çalışıyorum

Aşağıdaki tabloda kullanıcı kimliği 1'in 3 meyve türü olduğunu söylemek istiyorum. Verdiğim verilerde ayrıca boşluklar var, bu da googling'i bulduğum önerilerin çoğunu kırıyor gibi görünüyor.

İD meyve

id-1  elma

id-1  elma

id-1  muz

id-2  elma

id-2  muz

id-2  elma

id-1

id-1

id-1  armut

denenmiş:

=SUMPRODUCT(--(P:P>="id-1"),--(P:P<="id-1"),N:N)

=ArrayFormula(SUM(IF("id-1"=$P:$P,1/(COUNTIFS($P:$P,"id-1",$N:$N<>"",$N:$N<>"")),0)))

=SUM(IF(FREQUENCY(IF(P:P="id=1",N:N),N:N)>0,1))

Uzmanlık alanım değil, bu yüzden herhangi bir rehberlik için teşekkür ederim. Excel’i değil Google Sayfalarını kullanma.

Dizi formülü hesap makineleri yoğun işlem gördüğü için, sütun stili başvurusunun tamamını kullanmama konusunda uyarmak istediğim halde bu çalışmalı. Veri aralıklarınızın girdiğini biliyorsanız, aralıkları verilerin sınırlarına ayarlayın.

=ArrayFormula(SUM(IF(FREQUENCY(IF($A:$A="id-1",IF($B:$B<>"",MATCH($B:$B,$B:$B&"",0))),ROW($B:$B)-ROW($B$1)+1),1)))

Arama yapmak istediğiniz çok sayıda kimliğiniz varsa, "id-1" in değiştirilmesi gerekir, bu benzersiz kimlikleri başka bir sütuna koyabilir, sabit kodlu "id- #" yerine bu sütuna başvurabilir ve $ çapasını dışarıda bırakın ve formülü kopyalayın.

Ne yapıyor:

IF($A:$A="id-1",

Aralıktaki her satırın verilen dizgeyle eşleşip eşleşmediğini çözer, "id-1"

IF($B:$B<>"",

öyleyse, meyve sütunundaki yalnızca boş olmayan hücreleri kontrol eder

MATCH($B:$B,$B:$B&"",0)

ve her dizenin ilk bulunan oluşumunun satır dizinini bulur.

FREQUENCY(IF($A:$A="id-1",IF($B:$B<>"",MATCH($B:$B,$B:$B&"",0))),ROW($B:$B)-ROW($B$1)+1

Sonra kaç tane eşsiz meyvenin bulunduğunu bulur

IF(FREQUENCY(IF($A:$A="id-1",IF($B:$B<>"",MATCH($B:$B,$B:$B&"",0))),ROW($B:$B)-ROW($B$1)+1),1)

Ve benzersiz değerleri, her bir benzersiz değerin toplam sayımını almak için yukarıdaki ilk üç kodda bulunan değerlerle ilişkilendirir, ardından bulunan her dizgiye geçerli ID için bulunduğunu işaretlemek için tek bir 1 sayım atar.

SUM(IF(FREQUENCY(IF($A:$A="id-1",IF($B:$B<>"",MATCH($B:$B,$B:$B&"",0))),ROW($B:$B)-ROW($B$1)+1),1))

Ve son olarak, bu kimliği için bulunan tüm dizeleri toplar