boş satırda zsh sekmesi tamamlama

Bulamadığım bir tcsh'ism istiyorum: İçeriği olmayan boş bir satırda, sekme tuşuna basmak ve ls eşdeğerini görmek istiyorum. Demek istediğim

$ <tab>

başka bir şey yapmak için bana bir \ t. Komutun tamamlanması için harika kaynaklar buldum, ancak bu temel durum için değil. Bu konuda herhangi bir yardım harika olurdu! Teşekkürler.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

TabBir satırın başındaki davranışı stil tarafından kontrol edilir . Ancak, desteklenen iki davranış vardır:insert-tab

• her zamanki gibi tamamlanma zstyle ':completion:*' insert-tab false
• altına sekme ekle zstyle ':completion:*' insert-tab true
• biri ya da diğeri altında zstyle ':completion:*' insert-tab pending[=N]

Sadece bu pozisyondaki komutları tamamlamak istiyorsanız, zstyle ':completion:*' insert-tab trueyapacaktır. Geçerli dizindeki dosyaları listelemek gibi farklı bir şey istiyorsanız, değiştirmeniz gerekir _main_complete.

Bir zsh-işçiler listesinde son iplik tartışıldı insert-tab.

Boş satırda sekmeye bastığınızda, tcsh'nin otomatik listesinin zsh'da tam olarak uygulanması

% <TAB>

İşte burada:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

TCsh'yi daha yakından taklit etmek istiyorsanız, bunu .zshrc'nize de ekleyin:

unsetopt always_last_prompt       # print completion suggestions above prompt

Sadece boş bir satırda değil, aynı zamanda bir komut yazarken SEKME kullanımını geliştiren bu zsh widget'ı yazdım .

• Boş bir komut satırında ve herhangi bir komutun ortasında dosyaları listeler .
• Boş bir komut satırında dizinleri listeler .
• Boş bir komut satırında yürütülebilir dosyaları listeler .

Genel değişkenli durumlarda "cd" veya "./" başının başına gelecek şekilde yapılandırılabilir.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA