GVim'de font boyutunu nasıl değiştirebilirim?

Yerel komutları kullanarak fontun gVim'deki boyutunu değiştirmenin bir yolu var mı?

Ve değilse, hızlı bir şekilde yapmak için hangi komut dosyası kullanılabilir?

Set guifontSepetinde seçeneği .gvimrc. Bkz :help guifontve :help setting-guifont.

Özellikle, şöyle bir şey yapabilirsiniz: set guifont=Consolas:h11Windows'ta gvim'de 11 noktalı Konsollar kullanmak. Bazıları yalnızca belirli platformlarda mevcut olmasına rağmen, kalın harflerle ( :örneğin a ile ayrılmış ) kullanabileceğiniz birkaç seçenek :bvardır.

:hGösterildiği gibi yazı tipi boyutunu ayarlamak için bir seçenek muhtemelen en yararlı olan ve bir spesifik değişen ilişkin boyutunu istediğiniz gibi, yazı.

Çalışan bir GVim örneğinde font boyutunu değiştirmek istiyorsanız, şunu yazın:

:set guifont=*

İstenirse yeni bir yazı tipi seçmenin yanı sıra yazı tipi boyutunu belirlemenizi sağlayan bir pencere açılmalıdır. Daha sonra Vim'den ~/.gvimrcdeğişikliği kalıcı hale getirmek için ekleyeceğiniz satırı yazdırmasını isteyebilirsiniz :

:set guifont?

Durum satırında aşağıdaki gibi bir şey üretir:

guifont=Hasklig-Light:h16

Kalmak setiçin önek ile ekleyin ~/.gvimrc.

Yazı tipi değiştirmeden hızlı bir şekilde yazı tipi boyutunu değiştirmek için benim .vimrc içinde aşağıdaki var. Windows ve GTK'da çalışır. Diğer GUI'leri test etmedim. Başlangıçta başka birinden kopyaladığımdan eminim, ancak çok uzun zamandır rc dosyamdaydı, nereden geldiğini hatırlamıyorum.

if has("unix")
    function! FontSizePlus ()
      let l:gf_size_whole = matchstr(&guifont, '\( \)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole + 1
      let l:new_font_size = ' '.l:gf_size_whole
      let &guifont = substitute(&guifont, ' \d\+$', l:new_font_size, '')
    endfunction

    function! FontSizeMinus ()
      let l:gf_size_whole = matchstr(&guifont, '\( \)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole - 1
      let l:new_font_size = ' '.l:gf_size_whole
      let &guifont = substitute(&guifont, ' \d\+$', l:new_font_size, '')
    endfunction
else
    function! FontSizePlus ()
      let l:gf_size_whole = matchstr(&guifont, '\(:h\)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole + 1
      let l:new_font_size = ':h'.l:gf_size_whole
      let &guifont = substitute(&guifont, ':h\d\+$', l:new_font_size, '')
    endfunction

    function! FontSizeMinus ()
      let l:gf_size_whole = matchstr(&guifont, '\(:h\)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole - 1
      let l:new_font_size = ':h'.l:gf_size_whole
      let &guifont = substitute(&guifont, ':h\d\+$', l:new_font_size, '')
    endfunction
endif


if has("gui_running")
    nmap <S-F12> :call FontSizeMinus()<CR>
    nmap <F12> :call FontSizePlus()<CR>
endif

Görünüşe göre, yazı tipi ayarlarını yazma yolu platforma bağımlı. Benim için ne işe yaradı (MX Linux 17'deki gvim, (bir XFCE masaüstüyle Debian tabanlı bir Linux dağıtımı)):

• Geçerli font ayarlarını kullanarak açık bir gvim örneğinde : set guifont?

Örnek: guifont=DejaVu Sans Mono 12

• Ayarları (yazmak istediğiniz boyutu değiştirerek) ~/.gvimrcdosyaya yazmak, boşlukları ters eğik çizgi ile çıkmak ve boyuttan önce kullanmamak :için kullanın .

Örnek: set guifont=DejaVu\ Sans\ Mono\ 18

• Dosyayı kaydettikten sonra ~/.gvimrc, yeni gvim örneği istenen yeni boyutu kullanmalıdır.

Bu iki cevap bana yardımcı oldu:

• https://askubuntu.com/a/3532/129295
• https://stackoverflow.com/a/21894257/1878788

Bu yorumların yanı sıra:

• https://vi.stackexchange.com/a/3094/13481

Drew'un cevabına dayanarak bu kurulum benim için daha iyi çalıştı.

Bu artırır veya azaltır kullanarak font-size \+veya \-(varsayarak \senin lideridir) ve döngüleri kullanarak önceden tanımlanmış yazı tipleri aracılığıyla cot. Kaynak kodla mı yoksa metinle mi çalışıyorum bağlı olarak sık sık bu yazı tipleri arasında geçiş yapıyorum.

let g:fnt_types = ['SourceCode\ Pro', 'monofur' ]
let g:fnt_sizes = [ 10, 13 ]


let g:fnt_index = 0
let g:fnt_size  = g:fnt_sizes[g:fnt_index]

function! CycleFont()
  let g:fnt_index = (g:fnt_index + 1) % len(g:fnt_types)
  let g:fnt_size  = g:fnt_sizes[g:fnt_index]
  call ResetFont()
endfunction

function! ResetFont ()
  if has('gui_running')
    exe ':set guifont=' . g:fnt_types[g:fnt_index] . '\ ' . string(g:fnt_size)
  endif
endfunction

call ResetFont()

function! FontSizePlus ()
  let g:fnt_size = g:fnt_size + 0.5
  call ResetFont()
endfunction

function! FontSizeMinus ()
  let g:fnt_size = g:fnt_size - 0.5
  call ResetFont()
endfunction

nnoremap <leader>+ :call FontSizePlus()<cr>
nnoremap <leader>- :call FontSizeMinus()<cr>
nnoremap cot :call CycleFont()<cr>

Bu eklentiyi deneyebilirsiniz: vim-fontzoom .

map <m-o> :Fontzoom!<cr>
map <m--> <Plug>(fontzoom-smaller)
map <m-=> <Plug>(fontzoom-larger)