Son kullanıcı arayüzü komutunu tekrarlayabilir miyim?

.Son düzenleme komutunu tekrarlamak için kullanabileceğimi biliyorum .

Son UI manipülasyon komutunu tekrarlamanın bir yolu var mı? Örneğin, 10<C-W>-bir pencereyi on satır küçültmek için yazabilirim . ⟨Basına edebilmek için iyi olurdu bazı anahtarla Benim daha çok küçültmek istediğinizde kolayca bu komutu tekrarlamak için⟩.

Dot komutu .çalışır çünkü Vim arabelleklerin içeriğini değiştiren komutları "takip eder". Çalıştırırsanız :echo b:changedtick, geçerli arabellekteki her değişiklikle birlikte arttığını görürsünüz.

Ancak Vim, düzenleme yapmayan komutları "takip etmez". Böylece, hayır, istediğin şey yapılamaz.

Bunu vim'de varsayılan olarak yapmanın bir yolu yoktur, çünkü vim daha önce yürütülen wincmd'in kaydını tutmaz. Bununla birlikte, bunu bazı akıllı eşlemelerle yapmak mümkündür:

function! s:Wincmd(count, key)
    " If count is not zero, use the original count.  If otherwise, don't
    " include a count.
    let if_count = a:count ? a:count : ""
    " This builds a wincmd from the given key, and saves it so
    " it can be repeated.
    let g:last_wincmd = "wincmd " . nr2char(a:key)
    " Execute the built wincmd
    execute if_count . g:last_wincmd
endfunction

function! s:WincmdRepeat(count)
    " If no wincmd has been executed yet, don't do anything
    if !exists('g:last_wincmd') | return | endif
    " If a count is given, repeat the last wincmd that amount of times.
    " If otherwise, just repeat once.
    let if_count = a:count ? a:count : ""
    execute if_count . g:last_wincmd
endfunction

" Overwrite the default <C-w> mapping so that the last wincmd can be kept
" track of.  The getchar function is what captures the key pressed
" directly afterwards.  The <C-u> is to remove any cmdline range that vim
" automatically inserted.
nnoremap <silent> <C-w> :<C-u>call <SID>Wincmd(v:count, getchar())<CR>

" This just calls the function which repeats the previous wincmd.  It
" does accept a count, which is the number of times it should repeat the
" previous wincmd.  You can also replace Q with whatever key you want. 
nnoremap <silent> Q :<C-u> call <SID>WincmdRepeat(v:count)<CR>

Kullandığınız herhangi bir eşlemeniz <C-w>varsa, bunların yalnızca noreçeşitli olmadığında tekrarlanabileceğini unutmayın . Kullanılarak yayınlanan :wincmdhiçbir pencere tekrarlanmayacaktır. Ayrıca, birden fazla karakter içeren herhangi bir wincmds gerçekleştirilemez (örneğin <C-w>gf) .

İlgili Yardım Konuları

• :help v:count
• :help getchar()
• :help nr2char()
• :help expr1
• :help :wincmd
• :help :execute
• :help :for
• :help :map-<silent>
• :help c_CTRL-U
• :help <SID>

Alt mod eklentisi bu konuda yardımcı olabilir. Pencereyi yeniden boyutlandırmaya devam etmeyi <C-W>-tanımladığınız -(ve belki de +) yazdığınız bir "alt mod" yazabilirsiniz .

İstediğinizi yapabilen repmo.vim ("tekrar hareketleri") adında başka bir eklenti var .

Ancak hangi hareketleri (veya genel olarak eylemleri) tekrarlamak istediğinizi belirtmeniz gerekir . Benimki şu anda yapılandırıldı:

let g:repmo_mapmotions = "j|k h|l zh|zl g;|g, <C-w>w|<C-w>W"
let g:repmo_mapmotions .= " <C-w>+|<C-w>- <C-w>>|<C-w><"
let g:repmo_key = ";" 
let g:repmo_revkey = "," 

Bunu yaptıktan sonra tekrarlamak için 5 CTRL-W +vurabilirim ;.

Eklenti, belirtilen anahtarların her biri için eşlemeler oluşturarak çalışır.

Ne zaman fya da tkullanılırlar, ;ve ,eşleştirmeleri varsayılan davranışı geri temizlenir.

Daha g;önceki bir düzenleme noktasına geri dönmek için eşlemeyi özellikle kullanışlı buluyorum . g; ; ; ;