Google E-Tablolar'daki bir dizedeki kelime sayısını sayma

9

Metin dizeleri içeren basit bir Google e-tablom var. Sadece her hücrede bulunan kelime sayısını istiyorum. Kullanabileceğim yerleşik bir Google e-tablo işlevi var mı?

— user0
kaynak

9

Google E-Tablolar'da bunu biraz farklı yapardım.

formül

=COUNTA(SPLIT(A1, " "))

Açıklaması

SPLITİşlevi Google E-tablosunda kullanılabilir ve her alanı Hücrenin içeriğini bölecek ( " "). COUNTFonksiyon basitçe örneklerini sayar.

Excel formülü aynı cevabı veriyor, ancak biraz daha zahmetli:

=LEN(TRIM(A1))-LEN(SUBSTITUTE(A1," ",""))+1

Ekran görüntüsü

resim açıklamasını buraya girin

düşünce

Hangi formüllerin Google E-Tablolar için benzersiz olduğuna ilişkin aşağıdaki cevaba bakın:
https://webapps.stackexchange.com/a/44719/29140

— Jacob Jan Tuinstra
kaynak

1

Çoğunlukla bu benim için çalıştı (Google E-Tablolar'da) ... boş hücre 1 döndü hariç .. Böylece boş hücreler 0 döndürmek için biraz değiştirdim:=COUNTA(SPLIT(A1, " "))-IF(A1 = "",1,0)

— CenterOrbit

Benzer bir şey yapıyoruz ancak boşluklar normal boşluk karakteri (örneğin, sekmeler vb.) Olmadığında çalışmaz. Bu yüzden kelimeleri saymanın biraz zekice bir yolunu bulmak isterim.

— Aldo 'xoen' Giambelluca

Merhaba Aldo, en iyi soru burada Web Uygulamaları burada sormaktır !!!

— Jacob Jan Tuinstra

3

İçinde formüle edilen hafif iyileşme bu diğer cevap öylesine durumda A1 boş olduğunu veya boş dize varsa sıfır döndürür.

= EĞER (LEN (A1) = 0,0, COUNTA (SPLIT (A1, ""))

— Rubén
kaynak

0

Bunu bir hücre aralığında (yani A1:A25) yapmak istiyorsanız yukarıdaki formülü kullanabilirsiniz CHAR(32), boşluk karakteri nerede" "

=COUNTA(SPLIT(ARRAYFORMULA(CONCATENATE(A1:A25&CHAR(32)));CHAR(32)))

Bu, ilk hücrenin boş olmadığı durumlar dışında boş hücrelerle çalışır.

— Enrique Ramírez
kaynak

0

Bir diğeri:

=COUNTA(SPLIT(TRIM(A1&" #")," "))-1

Bu, hedef hücredeki her şeyin sonuna bir boşluk ve pound işareti ekler, buna null değerine ekleme de dahildir , bu nedenle sayımı atmak için hiçbir hata olmaz. Sonra sonunda geçici "sahte alanı" çıkarıyoruz.

— Erik Tyler
kaynak

0

=ARRAYFORMULA(IF(LEN(A3:A), 
 MMULT(IF(IFERROR(SPLIT(IF(LEN(A3:A), A3:A, ), " "))<>"", 1, 0), 
 ROW(INDIRECT("A1:A"&COUNTA(IFERROR(
 QUERY(IF(IFERROR(SPLIT(IF(LEN(A3:A), A3:A, ), " "))<>"", 1, 0), "limit 1", 0)))))^0), ))

______________________________________________________________

=ARRAYFORMULA(IF(LEN(A3:A), LEN(REGEXREPLACE(A3:A, "[^\s]", ))+1, ))

— user0
kaynak