Dosyaları birden çok hedefe yapıştırın

Bu duruma çok sık giriyorum ancak bir çözüm bulamadım. Panoda birkaç farklı hedef klasöre yapıştırıp + değiştirmem gereken bir grup CSS dosyası var. Klasör yapım şuna benzer

.
├── folderA_11
|   └── CSS
|        └── file1.css
|        └── file2.css
|        └── file3.css
├── folderB_11
|   └── CSS
|        └── file1.css
|        └── file2.css
|        └── file3.css
├── folderC_11
|   └── CSS
|        └── file1.css
|        └── file2.css
|        └── file3.css
├── folderD_22
|   └── CSS
|        └── file1.css
|        └── file2.css
|        └── file3.css
├── folderE_33
|   └── CSS
|        └── file1.css
|        └── file2.css
|        └── file3.css
└── folderF_44
    └── CSS
         └── file1.css
         └── file2.css
         └── file3.css
etc...

Bir kalıp var: Kabı sona eren tüm CSS klasörlerine yapıştırmak istiyorum _11 ama diğerlerinden hiçbiri değil.

Hedef klasörlerin içeriği önemli değil, sadece onları yeni dosyalarla değiştirmem gerekiyor. Bu dosyaları aynı anda birden fazla hedefe yapıştırmanın basit bir yolu var mı? Aynı zamanda bir Automator akışı veya Terminal komutu da olabilir.

1 - Automator'ı açın ve yeni bir Servis oluşturun:

2 - Servisi Finder'da Dosya ve Klasörü alacak şekilde ayarlayın:

3 - "Finder Öğeleri İste" eylemini sürükleyin:

4 - "Run AppleScript" eylemini sürükleyin:

5 - Bu kodu yapıştırın:

on run {input}
    set numItems to count input
    set theFile to item (numItems) of input as text
    set numItems to numItems - 1
    repeat while numItems is not 0
        tell application "Finder"
            duplicate file theFile to folder (item (numItems) of input as text) with replacing
            set numItems to numItems - 1
            delay 0.1
        end tell
    end repeat
    display dialog "File copied to all folders" buttons {"Thanks"} giving up after 5
end run

6 - İş akışınızı kaydedin ve istediğiniz şekilde adlandırın:

7 - KULLANIM: İstediğiniz sayıda klasör seçin, sağ tıklayın, hizmetler, iş akışınızı bulun:

Kopyalamak istediğiniz dosyayı seçin (pencerenin ana pencerenin arkasına gizlenebildiğinden emin olun):

"Seç" i tıklayın ve kopyasını bekleyin.

Not: dosya var olanları aynı isimle değiştirecek.

İstenildiği gibi, yorumlar başlığında tartıştığımız gibi uygulanabilir bir çözüm. Şu anda durum, panoda birden fazla hedef klasöre yapıştırılması gereken birden fazla dosyanızın olması. Bu hedef klasörlerin tümü denir "CSS" ve bir dizi ebeveyn klasörünün içinde bulunur (biten isimler "_11" ) toplu olarak seçebilirsiniz.

Bunu yaptıktan sonra, aşağıdakileri çalıştırabilirsiniz. Otomatikleştirici sağ tık bağlam menüsünden ya da altında seçerek hizmet Hizmetler (veya Mojave eşdeğeri); veya klavye kısayolu atayarak Sistem Tercihleri ve servisi bir kısayol tuşuna basarak tetikleyin.

Otomatikleştirici Söz konusu servis şuna benzer:

Kullanılan AppleScript kodu Run AppleScript eylem aşağıdadır. AppleScript, panoda bulunan dosyaların listesini okur; izole eder "CSS" servise gönderilen seçilen üst klasörlerin her birinde bulunan alt klasörler "CSS" önceden mevcut değilse klasör oluşturulur); ve sonra dosyaları panodan içine kopyalar. "CSS" dizinleri.

Panoda dosya yoksa, bir bip sesi duyarsınız ve başka işlem yapılmaz.

use framework "AppKit"

property this : a reference to current application
property NSPasteboard : a reference to NSPasteboard of this
property NSURL : a reference to NSURL of this


on run {input, parameters}
    set pb to NSPasteboard's generalPasteboard()
    set fs to (pb's readObjectsForClasses:[NSURL] options:[]) as list

    using terms from scripting additions
        -- No files on clipboard, nothing to do
        if fs = {} then return beep
    end using terms from

    tell application "Finder" to repeat with f in the input
        set css to (a reference to the folder named "CSS" in folder f)
        if not (exists css) then make new folder at f with properties ¬
            {name:"CSS"}

        duplicate fs to css with replacing
    end repeat
end run