Geçişli geri besleme yay seti (TFAS): NP-tam mı?

Bir süre önce, her iki setin de kardinalliği ile ilgili olmayan bir özelliği yerine getirdiği kenarların 2 bölümünü bulmak istediğimiz grafik sorunları için bir referans isteği gönderdim . Aşağıdaki sorunun NP zor olduğunu kanıtlamaya çalışıyordum:

Bir turnuvası verildiğinde , geçişli bir ilişki tanımlayan set edilmiş bir geri besleme yayı var mı?$G = (V,E)$$F \subseteq E$$G$

Bir ispat girişiminde bulunmak için bir inşaatım var, ancak bunun çıkmaz bir yere gireceği anlaşılıyor, bu yüzden burada bariz bir şeyi kaçırıp kaçırmadığımı görmek isteyebileceğimi düşündüm. Yaratıcılığınızı kullandıklarımıza benzer düşünce çizgileriyle sınırlamak için, denememi burada yayınlamayacağım.

Bu problem NP zor mu? Eğer öyleyse, nasıl kanıtlanır?

Küçük bir bağlam eklemek için, geçişli geri besleme yayı ayarlanmamış bir grafik için bir yapı. Bu yapım için aşağıdaki gadget grafiğini kullanacağım:

Bu turnuva aşağıdaki özelliklere sahiptir (bir program kullanarak kontrol ettim, resmi olarak kanıtlamadım):

• (2,7) belirli bir TFAS'ta değilse, (1,3)
• (5,1) belirli bir TFAS içindeyse, (3,6)
• (7,3) belirli bir TFAS'ta ise (5,1)

veya yüklem mantığı gösterimini biraz kötüye kullanma:

• $\neg (2,7) \rightarrow (1,3)$
• $(5,1) \rightarrow (3,6)$
• $(7,3) \rightarrow \neg (5,1)$

Her çıkarım için, iki kenarın çift olarak ayrık olduğunu fark edeceksiniz, bu nedenle aşağıdaki inşaat çalışır:

Umarım grafik fikrini ortaya koyabilirsiniz: yukarıdaki turnuvanın ima özelliklerini kullanarak, her geçişli geribildirim yayının hem kenarını hem de kenarını , yani bir çelişkiyi içerdiği ve içermediği bir grafik oluşturabiliriz. grafikte geçişli bir geri besleme yayı seti yoktur. Aynı çelişki herhangi bir tamamlamada kalacağından, bu grafiğin tamamlanması da bir tane olamaz. Hepsi çıkarımlar için yukarıdaki turnuvanın yerini alarak türetilebilecek çok sayıda köşe noktası bıraktım.$A$

TFAS olmadan hiçbir grafik bildirmeyen kısa bir clingo programı çalıştırdım, ancak bir hata vardı. Düzelttim ve şimdi n = 8 veya daha az bir TFAS olmadan grafik olmadığını doğrular. N = 9 için bunu bulur:

is_edge(edge(2,3)) is_edge(edge(1,4)) is_edge(edge(2,4)) is_edge(edge(3,5)) is_edge(edge(4,5)) is_edge(edge(1,6)) is_edge(edge(2,6)) is_edge(edge(3,6)) is_edge(edge(5,6)) is_edge(edge(1,7)) is_edge(edge(4,7)) is_edge(edge(5,7)) is_edge(edge(6,7)) is_edge(edge(1,8)) is_edge(edge(3,8)) is_edge(edge(4,8)) is_edge(edge(5,9)) is_edge(edge(6,9)) is_edge(edge(7,9)) is_edge(edge(2,1)) is_edge(edge(3,1)) is_edge(edge(4,3)) is_edge(edge(5,1)) is_edge(edge(5,2)) is_edge(edge(6,4)) is_edge(edge(7,2)) is_edge(edge(7,3)) is_edge(edge(8,2)) is_edge(edge(8,5)) is_edge(edge(8,6)) is_edge(edge(8,7)) is_edge(edge(9,1)) is_edge(edge(9,2)) is_edge(edge(9,3)) is_edge(edge(9,4)) is_edge(edge(9,8))

İşte (sabit) kodlama

% tfas.asp
#show is_edge/1.
vertex(1..n).

opp_edges(edge(A,B),edge(B,A)) :- vertex(A), vertex(B), A < B.
possible_edge(E1;E2) :- opp_edges(E1,E2).

{is_edge(E1); is_edge(E2)} = 1 :- opp_edges(E1, E2).
ntfas(E) :- possible_edge(E), not is_edge(E).
ntfas(edge(X, X)) :- vertex(X).

tfas(E) | fs(E) :- is_edge(E).
ntfas(E) :- fs(E).

broken :- ntfas(edge(A,C)), tfas(edge(A, B)), tfas(edge(B,C)).

reachable(X, Y) :- fs(edge(X, Y)), is_edge(edge(X, Y)).
reachable(X, Z) :- reachable(X, Y), fs(edge(Y, Z)), is_edge(edge(Y, Z)).
broken :- reachable(X, X).

tfas(E) :- broken, possible_edge(E).
fs(E) :- broken, possible_edge(E).
:- not broken.

clingo -c n=7 tfas.aspŞununla çalıştır (clingo 4.2.1 kullanarak)

(n = 7, tam olarak 7 köşeli grafikleri gösterir)

Yalnızca 7 köşede TFAS içermeyen bir grafik varsa ve tatmin edici olmalıdır.

Tamam, @ G.Bach'ın hangi grafiği açıkladığını ve clingo'da kodladığını anladım (aşağıdaki clingo açıklamasına bakın. Gadget grafiğinin bir açıklamasıyla başlar ve tam kopyasını almak için kopyalarının nasıl birleştirileceğini açıklar 34-vertex turnuva grafiği G.Bach açıklıyor. Ben de topraklı grafik açıklamasını ekledim).

Daha sonra bu grafik üzerinde clingo çalıştırmaya devam ettim ve 241 kenarlı bir TFAS bulduğunu iddia etti. Ama grafik kodlamasında bir hata yaptım. Hatayı düzelttim ve clingo şimdi tatmin edilemez raporlar (yani TFAS yok).

İşte bir grafik üzerinde TFAS bulmak için program

{tfas(E)} :- is_edge(E).
:- not tfas(edge(A,C)), tfas(edge(A, B)), tfas(edge(B,C)).

reachable(X, Y) :- not tfas(edge(X, Y)), is_edge(edge(X, Y)).
reachable(X, Z) :- reachable(X, Y), not tfas(edge(Y, Z)), is_edge(edge(Y, Z)).
:- reachable(X, X).

tfas_count(N) :- N = #count{tfas(E) : tfas(E)}.

#show tfas/1.
#show tfas_count/1.

İşte G.Bach'ın grafiğini oluşturmak için (güncellenmiş) program. Grafiğin iyi biçimlendirilmiş bir turnuva grafiği olup olmadığını kontrol etmek için sonuna göstergeler ekledim:

gadget_vertex(0..7).

gadget_edge(0,1).
gadget_edge(0,2).
gadget_edge(0,3).
gadget_edge(0,4).
gadget_edge(1,2).
gadget_edge(1,3).
gadget_edge(1,6).
gadget_edge(1,7).
gadget_edge(2,3).
gadget_edge(2,4).
gadget_edge(2,5).
gadget_edge(2,7).
gadget_edge(3,4).
gadget_edge(3,5).
gadget_edge(3,6).
gadget_edge(4,1).
gadget_edge(4,5).
gadget_edge(4,6).
gadget_edge(4,7).
gadget_edge(5,0).
gadget_edge(5,1).
gadget_edge(5,6).
gadget_edge(6,0).
gadget_edge(6,2).
gadget_edge(6,7).
gadget_edge(7,0).
gadget_edge(7,3).
gadget_edge(7,5).

special_edge(a;b;c;d;e).

forces(a,b).
forces(b,c).
forcesn(c,a).
nforces(a,d).
forces(d,e).
forces(e,a).

relates(A,B) :- forces(A,B).
relates(A,B) :- nforces(A,B).
relates(A,B) :- forcesn(A,B).

is_se_pair(se_pair(A,B)) :- relates(A,B).
vertex_name(v(V,P)) :- gadget_vertex(V), is_se_pair(P).

matches(from(A), v(5, se_pair(A,B))) :- forces(A,B).
matches(to(A), v(1, se_pair(A,B))) :- forces(A,B).
matches(from(B), v(3, se_pair(A,B))) :- forces(A,B).
matches(to(B), v(6, se_pair(A,B))) :- forces(A,B).

matches(from(A), v(2, se_pair(A,B))) :- nforces(A,B).
matches(to(A), v(7, se_pair(A,B))) :- nforces(A,B).
matches(from(B), v(1, se_pair(A,B))) :- nforces(A,B).
matches(to(B), v(3, se_pair(A,B))) :- nforces(A,B).

matches(from(A), v(7, se_pair(A,B))) :- forcesn(A,B).
matches(to(A), v(3, se_pair(A,B))) :- forcesn(A,B).
matches(from(B), v(5, se_pair(A,B))) :- forcesn(A,B).
matches(to(B), v(1, se_pair(A,B))) :- forcesn(A,B).

same_vertex(V, V) :- vertex_name(V).
same_vertex(M, N; N, M) :- matches(X, M), matches(X, N).

already_found(v(Y,N2)) :- vertex_name(v(X,N1)), same_vertex(v(X,N1),v(Y,N2)), N1 < N2.
vertex(V) :- vertex_name(V), not already_found(V).

named_gadget_edge(edge(v(X,SE),v(Y,SE))) :- gadget_edge(X,Y), is_se_pair(SE).
from_gadget_edge_named(edge(A, B), edge(C,D)) :- named_gadget_edge(edge(C,D)), same_vertex(A,C), same_vertex(B,D), vertex(A), vertex(B).
from_gadget_edge(edge(A,B)) :- from_gadget_edge_named(edge(A,B),edge(C,D)).
is_edge(E) :- from_gadget_edge(E).
is_edge(edge(A,B)) :- vertex(A), vertex(B), A < B, not from_gadget_edge(edge(B,A)).

vertex_count(VN) :- VN = #count{vertex(V) : vertex(V)}.
edge_count(EN) :- EN = #count{is_edge(E) : is_edge(E)}.

#show vertex_count/1.
#show edge_count/1.

bidirectional :- is_edge(edge(A,B)), is_edge(edge(B,A)).
phantom_vertex :- is_edge(edge(A,B)), not vertex(A).
phantom_vertex :- is_edge(edge(A,B)), not vertex(B).
incomplete :- vertex(A), vertex(B), not is_edge(edge(A,B)), not is_edge(edge(B,A)), A != B.

#show bidirectional/0.
#show phantom_vertex/0.
#show incomplete/0.

SWAG varsayımı [hiçlikten daha iyi bir şey mi?]:

Bir turnuvası verildiğinde , geçişli bir ilişki tanımlayan dizisi ayarlanmış bir geri besleme yayı vardır . dolayısıyla sorunF ⊆ E G O ( 1 $G = (V,E)$$F \subseteq E$$G$$O(1)$

^{notlar: aşağı sayım hiçbiri şimdiye kadar verilmemiş gibi görünüyor. daha da iyisi, belirli grafik sınıflarıyla ilgili kenar yönelim kalıplarının gözlemleri olabilir. ya da biraz daha fazla motivasyon veya mevcut literatüre bağlamak. Kanıtlar ve çürütmeler tarzında sunulan (Lakatos) ... Ayrıca, [henüz?] çok fazla ilgili olmayan, deneysel olarak çalışma önermek gibi sıradışı bir sorun gibi görünüyor ....}