Bir hatayla karşılaştığında toplu iş dosyasının sonlandırılmasını nasıl sağlayabilirim?

Farklı parametreleri ile tekrar tekrar aynı yürütülebilir çağıran bir toplu iş dosyası var. Çağrılardan biri herhangi bir düzeydeki hata kodunu döndürürse derhal sonlandırılmasını nasıl sağlayabilirim?

Temel olarak, MSBuild'in eşdeğerini istiyorum ContinueOnError=false.

Giriş errorlevelbir in ifardından açıklamada ve exit /b(çıkmak b 0'dan başka değerler için atch dosyasını değil, yalnızca tüm cmd.exe süreci).

same-executable-over-and-over.exe /with different "parameters"
if %errorlevel% neq 0 exit /b %errorlevel%

Hata seviyesinin değerinin toplu iş dosyanızın dışına yayılmasını istiyorsanız

if %errorlevel% neq 0 exit /b %errorlevel%

ama eğer bu bir içindeyse forbiraz zorlaşır. Daha fazla şeye ihtiyacınız olacak:

setlocal enabledelayedexpansion
for %%f in (C:\Windows\*) do (
    same-executable-over-and-over.exe /with different "parameters"
    if !errorlevel! neq 0 exit /b !errorlevel!
)

Düzenle: Her komuttan sonra hatayı kontrol etmeniz gerekir. Cmd.exe / command.com toplu işinde global bir "hataya gitme" türü yoktur. XP veya Vista'da toplu iş korsanlığımın hiçbirinde olumsuz bir hata düzeyiyle karşılaşmamamıza rağmen, CodeMonkey'e göre kodumu da güncelledim .

|| goto :labelHer satıra ekleyin ve ardından a :label.

Örneğin, bu .cmd dosyasını oluşturun:

@echo off

echo Starting very complicated batch file...
ping -invalid-arg || goto :error
echo OH noes, this shouldn't have succeeded.
goto :EOF

:error
echo Failed with error #%errorlevel%.
exit /b %errorlevel%

Toplu iş dosyası alt yordamından çıkma ile ilgili soruya da bakın .

En kısa:

command || exit /b

Gerekirse, çıkış kodunu ayarlayabilirsiniz:

command || exit /b 666

Ayrıca şunları da kaydedebilirsiniz:

command || echo ERROR && exit /b

Küçük bir güncelleme, "eğer hata seviyesi 1" için kontrolleri aşağıdaki şekilde değiştirmeniz gerekir ...

IF %ERRORLEVEL% NEQ 0 

Bunun nedeni XP'de negatif sayıları hata olarak alabilmenizdir. 0 = sorun yok, başka bir şey sorun.

Ve DOS "ERRORLEVEL IF" testlerini işleme biçimini unutmayın. Kontrol ettiğiniz sayı bu sayı veya daha yüksekse true değerini döndürecektir, bu nedenle belirli hata numaraları arıyorsanız 255 ile başlayıp aşağı doğru çalışmanız gerekir.

İşte BASH ve Windows CMD için bir dizi komut çalıştıran ve bunlardan herhangi biri başarısız olursa çıkmayı sağlayan bir çok dilli program :

#!/bin/bash 2> nul

:; set -o errexit
:; function goto() { return $?; }

command 1 || goto :error

command 2 || goto :error

command 3 || goto :error

:; exit 0
exit /b 0

:error
exit /b %errorlevel%

Geçmişte bu tür bir şeyi çoklu platform sürekli entegrasyon komut dosyası için kullandım.

Onları en okunabilir bulduğum için OR komutunu tercih ederim (her komuttan sonra bir if olması yerine). Ancak bunu yapmanın naif yolu command || exit /b %ERRORLEVEL%olduğunu yanlış .

Bunun nedeni, bir satır, bir satır ilk okunduğunda değil, kullanıldığında değil değişkenleri genişletmesidir. Bu, commandyukarıdaki satırda başarısız olursa, toplu iş dosyasının düzgün bir şekilde çıktığı, ancak 0 dönüş koduyla çıktığı anlamına gelir , çünkü değerin %ERRORLEVEL%satırın başında olduğu şey budur . Açıkçası, bu senaryomuzda istenmeyen bir durumdur, bu nedenle gecikmeli genişlemeyi etkinleştirmeliyiz , şöyle:

SETLOCAL EnableDelayedExpansion

command-1 || exit /b !ERRORLEVEL!
command-2 || exit /b !ERRORLEVEL!
command-3 || exit /b !ERRORLEVEL!
command-4 || exit /b !ERRORLEVEL!

Bu snippet, 1-4 komutlarını yürütür ve bunlardan herhangi biri başarısız olursa, başarısız komutuyla aynı çıkış koduyla çıkar.

Her zaman ERRORLEVEL'e güvenemeyiz, çünkü çoğu kez harici programlar veya toplu komut dosyaları çıkış kodlarını döndürmez.

Bu durumda, aşağıdaki gibi arızalar için genel kontrolleri kullanabiliriz:

IF EXIST %outfile% (DEL /F %outfile%)
CALL some_script.bat -o %outfile%
IF NOT EXIST %outfile%  (ECHO ERROR & EXIT /b)

Ve program konsol için bir şey çıkarırsa, bunu da kontrol edebiliriz.

some_program.exe 2>&1 | FIND "error message here" && (ECHO ERROR & EXIT /b)
some_program.exe 2>&1 | FIND "Done processing." || (ECHO ERROR & EXIT /b)

Nasıl denediğim önemli değil, msbuild başarısız olsa bile hata seviyesi her zaman 0 olarak kalır. Bu yüzden geçici çözümümü oluşturdum:

Proje oluşturma ve günlüğü Build.log dosyasına kaydetme

SET Build_Opt=/flp:summary;logfile=Build.log;append=true

msbuild "myproj.csproj" /t:rebuild /p:Configuration=release /fl %Build_Opt%

build log'da "0 Error" dizesini arayın, sonucu var olarak ayarlayın

FOR /F "tokens=* USEBACKQ" %%F IN (`find /c /i "0 Error" Build.log`) DO (
    SET var=%%F
)
echo %var%

arama dizesini kaç satır içerdiğini gösteren son karakteri al

set result=%var:~-1%

echo "%result%"

dize bulunamazsa, hata> 0, derleme başarısız oldu

if "%result%"=="0" ( echo "build failed" )

Bu çözüm, Mechaflash'ın bir toplu iş dosyasında komut çıktısını değişken olarak ayarlama konusundaki gönderisinden ilham aldı

ve https://ss64.com/nt/syntax-substring.html

@echo off

set startbuild=%TIME%

C:\WINDOWS\Microsoft.NET\Framework\v3.5\msbuild.exe c:\link.xml /flp1:logfile=c:\link\errors.log;errorsonly /flp2:logfile=c:\link\warnings.log;warningsonly || goto :error

copy c:\app_offline.htm "\\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm"

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\bin\ /Q

echo Start Copy: %TIME%

set copystart=%TIME%

xcopy C:\link\_PublishedWebsites\OperationsLink \\lawpccnweb01\d$\websites\OperationsLinkWeb\ /s /y /d

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm

echo Started Build: %startbuild%
echo Started Copy: %copystart%
echo Finished Copy: %TIME%

c:\link\warnings.log

:error

c:\link\errors.log